dev-python/django: Bump to 3.0.14

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index b3fd29657579..9127ce9a18dc 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -2,6 +2,8 @@ DIST Django-2.2.19.checksum.txt 2563 BLAKE2B 746ba6ba9ea4edba7641e8f32c6022be76b
 DIST Django-2.2.19.tar.gz 9209434 BLAKE2B 0928a06d467ba9d643693cf6ffba358c05a739c6dca6199853a4debeb064748c8c56d57b768eb283ccd9cc4afe5fc192636d8270aec93108b4bcce57be5003ed SHA512 92f2200f147766349526d21b5240307e4f082f97fc5b80b55777330068a9da5eaa9941360ccdd729573d015d9a7a0430461f1ac61f749a0475c006981d8775ea
 DIST Django-3.0.13.checksum.txt 2563 BLAKE2B ef243cc9621c73ebf84e47292a18a41309eb51464a57a48084a3bfc086f9d9065c94d935136c47e0cd0f01243c4c49036a2bdaa96aac45389d25f1e085598ed7 SHA512 be4768c8ce5dddb26edfd4385da11eba9be3814bd58da6c74354d044860f6cc8805b1533169030c4a8d411d27152d40b5c7f067458dda9a11d893acd5c160baa
 DIST Django-3.0.13.tar.gz 9285769 BLAKE2B 9be51ec02119b79baa4f107f296c8b72920449eb846c3cd686b0d20417330eed4db1beedaaa3778ba45e0685cc4210325a4fdf04a979a028ad5360b9f160da09 SHA512 af4e4d1491ccd7edb4363f55a78f39850b55b544cceabaf8d94a3a7a866d29a63badfb41c834cefad3cadae612f2b074f9deacde5c5ee183c55f853c687c730c
+DIST Django-3.0.14.checksum.txt 2553 BLAKE2B 142b407d6573cac8d07a140370123ce3996433742a67907cedff340741f36b0f82fb577a671929a938967b810d25cf2f491ff85241e6a25782e216eb5571c89f SHA512 3c0ec40c42b23d0213df540eeecb3d8dfc8590ccdbd2c5e8fab598a09dff0408364ea3c8836963e94205e0086c96bd64b8a049a62b9250c6b0c5850cf8d834db
+DIST Django-3.0.14.tar.gz 9259569 BLAKE2B 454b91900a9d8cf81f6227adb465e4f9e0da16e4ddab40fa4a1c66ab131832088dd89be129ec97fd70dc8725e826e7da2c657c87c2339db64dd3eba410a91eb3 SHA512 d503f99417479e5c8be928981c14517c519adc88923efaec691cf090b4d9de77424d9ca5dae09a29dae4cb5e962cd86bbfb39cc86c3e910d45bc1757cf169d4a
 DIST Django-3.1.7.checksum.txt 2554 BLAKE2B 4df811f7bf1c502d4ab6031a92a07dbda24c6e67c31cd76dc68d1f29bb01ac376151f4e3f534a8293f7e10f98d0132b2f3359002ee424a9dbda3e5ab7b4e2f28 SHA512 94a93927fcb72cff5930ff824274ba5e6b0491e92d3b8b5973ed4884251cd16b1fa27816e02fd7bccdd671d8dc24523ef6713b54c10aae2cfde11e8ce5730fce
 DIST Django-3.1.7.tar.gz 9673009 BLAKE2B 89b1618365b09edb7714dbb8b8361d6d1918e673175e63536a31615d5115bfd5e2a7e3918991bcf4f576deb998019e449f4a8c37b5868a4b4ea82a0340984703 SHA512 a8a24f7f25ff2f3a7b5ebe4cef08c7f1303c78bd33f9a53c10630159d6895a738e863dc1034ad0817ad89275c202b4319aa5949ce89f36ca0b537c8a5c0c407c
 DIST Django-3.1.8.checksum.txt 2544 BLAKE2B e62097ab681f16fb9732b656a05edc77673e3eefd81112bb7d362857c81f3d3f16baeb354e48f5989be8044df11440436ea39315d8c5f573968e93a54d310a3e SHA512 7c41575a3ee18f0db07b51a02ec780cf51a4cd375879c368f1b3dca405b13d1fec303bd2b85a38732c4a371c8aee7ec49fa5e12d3e1c88295a8c5e6e65f7b9c7
diff --git a/dev-python/django/django-3.0.14.ebuild b/dev-python/django/django-3.0.14.ebuild
new file mode 100644
index 000000000000..aa3966fb1d19
--- /dev/null
+++ b/dev-python/django/django-3.0.14.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="https://www.djangoproject.com/ https://pypi.org/project/Django/"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/asgiref-3.3.2[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+		!!<dev-python/ipython-7.21.0-r1
+		!!=dev-python/ipython-7.22.0-r0
+	)
+	verify-sig? ( app-crypt/openpgp-keys-django )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.0.6-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+src_prepare() {
+	# do not bind to a specific version
+	# https://bugs.gentoo.org/750695
+	sed -i -e 's:asgiref ~= 3.2:asgiref:' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}