dev-ruby/addressable: add 2.6.0

Signed-off-by: Hans de Graaff <graaff@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-ruby/addressable/addressable-2.6.0.ebuild b/dev-ruby/addressable/addressable-2.6.0.ebuild
new file mode 100644
index 000000000000..d47bd69d4db5
--- /dev/null
+++ b/dev-ruby/addressable/addressable-2.6.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby23 ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_EXTRADOC="README.md CHANGELOG.md"
+
+RUBY_FAKEGEM_EXTRAINSTALL="data"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A replacement for the URI implementation that is part of Ruby's standard library"
+HOMEPAGE="https://rubygems.org/gems/addressable https://github.com/sporkmonger/addressable"
+
+LICENSE="Apache-2.0"
+
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="doc test"
+
+ruby_add_rdepend ">=dev-ruby/public_suffix-2.0.2:* <dev-ruby/public_suffix-4:*"
+
+ruby_add_bdepend "test? ( dev-ruby/rspec-its )"
+
+all_ruby_prepare() {
+	# Remove spec-related tasks so that we don't need to require rspec
+	# just to build the documentation, bug 383611.
+	sed -i -e '/spectask/d' Rakefile || die
+	rm -f tasks/rspec.rake || die
+	sed -i -e '/bundler/ s:^:#:' \
+		-e '/^begin/,/^end/ s:^:#:' \
+		spec/spec_helper.rb || die
+
+	# Remove specs requiring network connectivity
+	rm -f spec/addressable/net_http_compat_spec.rb || die
+
+	# Remove spec that tests against an unreleased github fork
+	rm -f spec/addressable/rack_mount_compat_spec.rb || die
+}