dev-ruby/amatch: add 0.4.0

Package-Manager: Portage-2.3.6, Repoman-2.3.2

1 files changed, 40 insertions, 0 deletions

diff --git a/dev-ruby/amatch/amatch-0.4.0.ebuild b/dev-ruby/amatch/amatch-0.4.0.ebuild
new file mode 100644
index 000000000000..30a275a074dc
--- /dev/null
+++ b/dev-ruby/amatch/amatch-0.4.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby21 ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="CHANGES README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="Approximate Matching Extension for Ruby"
+HOMEPAGE="https://flori.github.com/amatch/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE=""
+
+ruby_add_rdepend "=dev-ruby/tins-1*"
+
+all_ruby_prepare() {
+	# mize is listed as a dependency but not actually used
+	sed -i -e '/mize/d' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext extconf.rb || die
+}
+
+each_ruby_compile() {
+	emake -Cext V=1
+	cp ext/amatch_ext$(get_modname) lib/ || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib -S testrb-2 tests/* || die
+}