dev-ruby/capistrano: add 3.11.2

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-ruby/capistrano/capistrano-3.11.2.ebuild b/dev-ruby/capistrano/capistrano-3.11.2.ebuild
new file mode 100644
index 000000000000..458dc74b07cb
--- /dev/null
+++ b/dev-ruby/capistrano/capistrano-3.11.2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_RECIPE_DOC="none"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A distributed application deployment system"
+HOMEPAGE="https://capistranorb.com/"
+
+LICENSE="MIT"
+SLOT="3"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_rdepend "
+	>=dev-ruby/airbrussh-1.0.0
+	>=dev-ruby/sshkit-1.9:0
+	>=dev-ruby/rake-10.0.0
+	dev-ruby/i18n:*
+	!!<dev-ruby/capistrano-2.15.5-r2"
+ruby_add_bdepend "
+	test? (	dev-ruby/mocha )"
+
+all_ruby_prepare() {
+	# Avoid specs that depend on capistrano already being installed
+	rm -f spec/lib/capistrano/doctor/gems_doctor_spec.rb || die
+
+	# Avoid specs that require a TTY
+	sed -i -e '/asking for a variable/,/^  end/ s:^:#:' spec/integration/dsl_spec.rb || die
+	rm -f spec/lib/capistrano/configuration/question_spec.rb || die
+}