dev-ruby/childprocess: add 0.9.0

Package-Manager: Portage-2.3.24, Repoman-2.3.6

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-ruby/childprocess/childprocess-0.9.0.ebuild b/dev-ruby/childprocess/childprocess-0.9.0.ebuild
new file mode 100644
index 000000000000..3fdfcee15242
--- /dev/null
+++ b/dev-ruby/childprocess/childprocess-0.9.0.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby23 ruby24 ruby25"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Solution for controlling external programs running in the background"
+HOMEPAGE="https://github.com/jarib/childprocess"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+ruby_add_rdepend ">=dev-ruby/ffi-1.0.11"
+
+all_ruby_prepare() {
+	# Remove bundler support
+	rm Gemfile || die
+	sed -i -e "/[Bb]undler/d" Rakefile || die
+	sed -i -e "/[Cc]overalls/d" spec/spec_helper.rb || die
+	sed -i -e 's/git ls-files/find/' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_prepare() {
+	sed -i -e "s:'ruby':'"${RUBY}"':" spec/childprocess_spec.rb || die
+}
+
+each_ruby_test() {
+	RUBYLIB=lib RSPEC_VERSION=3 ruby-ng_rspec
+}