dev-ruby/dalli: add 2.7.11

Closes: https://bugs.gentoo.org/719344
Closes: https://bugs.gentoo.org/738656
Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-ruby/dalli/dalli-2.7.11.ebuild b/dev-ruby/dalli/dalli-2.7.11.ebuild
new file mode 100644
index 000000000000..a8a2a8ccf9e1
--- /dev/null
+++ b/dev-ruby/dalli/dalli-2.7.11.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby25 ruby26 ruby27"
+
+RUBY_FAKEGEM_TASK_TEST="test"
+
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="History.md Performance.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A high performance pure Ruby client for accessing memcached servers"
+HOMEPAGE="https://github.com/petergoldstein/dalli"
+SRC_URI="https://github.com/petergoldstein/dalli/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~x86"
+IUSE=""
+
+DEPEND+="${DEPEND} test? ( >=net-misc/memcached-1.5.4 )"
+
+ruby_add_bdepend "test? (
+		dev-ruby/minitest:5
+		>=dev-ruby/mocha-0.13
+		dev-ruby/rack
+		>=dev-ruby/activesupport-5.2
+		dev-ruby/connection_pool )"
+
+all_ruby_prepare() {
+	chmod 0755 "${HOME}" || die "Failed to fix permissions on home"
+
+	sed -i -e '/\(appraisal\|bundler\)/ s:^:#:' Rakefile || die
+
+	sed -i -e '3igem "minitest", "~> 5.0"; gem "activesupport", ">=5.2.0"' \
+		-e '/bundler/ s:^:#:' test/helper.rb || die
+
+	# Drop rails dependency which is only used to display the version
+	# number, so we only need to depend on activesupport and avoid
+	# complicated circular dependencies.
+	sed -i -e '/rails/I s:^:#:' \
+		-e '14irequire "active_support"' test/helper.rb || die
+
+	# Fix test compatability with memcached 1.5.4 and higher
+	# https://github.com/petergoldstein/dalli/pull/672
+	#sed -i -e '/memcached_low_mem_persistent/,/^end/ s/-M/-M -I 512k/' test/memcached_mock.rb || die
+}