dev-ruby/domain_name: add 0.6.20231109

Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-ruby/domain_name/domain_name-0.6.20231109.ebuild b/dev-ruby/domain_name/domain_name-0.6.20231109.ebuild
new file mode 100644
index 000000000000..6e9270ee8cae
--- /dev/null
+++ b/dev-ruby/domain_name/domain_name-0.6.20231109.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby31 ruby32"
+
+RUBY_FAKEGEM_RECIPE_TEST="none"
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Domain Name manipulation library for Ruby"
+HOMEPAGE="https://github.com/knu/ruby-domain_name"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="test"
+
+ruby_add_bdepend "
+	test? (
+		>=dev-ruby/test-unit-2.5.5
+		dev-ruby/shoulda
+	)"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/,/end/ d' test/helper.rb || die
+	rm Gemfile* || die
+
+	# Remove development dependencies
+	sed -i -e '/dependency.*\(shoulda\|bundler\|jeweler\|rdoc\)/d' \
+		${RUBY_FAKEGEM_GEMSPEC} || die
+
+	# Avoid dependency on git.
+	sed -i -e 's/`git ls-files`/""/' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_test() {
+	ruby-ng_testrb-2 -Ilib:test test/test_*.rb
+}