dev-ruby/elasticsearch-extensions: import of 0.0.33

New dependency for elasticsearch-api.

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-ruby/elasticsearch-extensions/elasticsearch-extensions-0.0.33.ebuild b/dev-ruby/elasticsearch-extensions/elasticsearch-extensions-0.0.33.ebuild
new file mode 100644
index 000000000000..b6b127aa4e8c
--- /dev/null
+++ b/dev-ruby/elasticsearch-extensions/elasticsearch-extensions-0.0.33.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27"
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+RUBY_FAKEGEM_TASK_TEST="NOTURN=true test"
+
+inherit ruby-fakegem
+
+MY_P=elasticsearch-ruby-${PV}
+DESCRIPTION="Ruby integrations for ES, elasticsearch-extensions module"
+HOMEPAGE="https://github.com/elastic/elasticsearch-ruby"
+SRC_URI="https://github.com/elastic/elasticsearch-ruby/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_rdepend "
+	dev-ruby/ansi
+	dev-ruby/elasticsearch
+"
+ruby_add_bdepend "
+	doc? ( dev-ruby/yard )
+	test? (
+		dev-ruby/mocha:1.0
+		dev-ruby/pry
+		dev-ruby/rspec:3
+		dev-ruby/shoulda-context
+		dev-ruby/curb
+		dev-ruby/patron
+	)
+"
+
+RUBY_S=${MY_P}/${PN}
+
+all_ruby_prepare() {
+	# fix to work without git
+	sed -i -e 's/git ls-files/find * -type f/' *.gemspec || die
+
+	# remove useless dependencies from Rakefile
+	sed -e '/bundler/d' \
+		-e '/require.*cane/,/end/d' \
+		-i Rakefile || die
+
+	sed -e '/reporters/I s:^:#:' \
+		-i test/test_helper.rb || die
+}