dev-ruby/kramdown: [QA] revbump for changed RDEPEND

It's necessary to have a revision bump for changes in RDEPEND,
but especially where we're changing the providers of an
any-of || ( ... ) dependency.

In this case, if one already has edbrowse installed,
once/if tidy-html5 is masked for removal (which seems to be
the plan), there's no reason the package manage is obligated
to realise that the existing ebuild was modified to allow
htmltidy instead. Hence, a revision bump is required
to apply the metadata change.

Fixes: 22d74ef60f5bf00571639586f8e4e705420614a9
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-ruby/kramdown/kramdown-2.3.1-r1.ebuild b/dev-ruby/kramdown/kramdown-2.3.1-r1.ebuild
new file mode 100644
index 000000000000..54eced4e6f64
--- /dev/null
+++ b/dev-ruby/kramdown/kramdown-2.3.1-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby25 ruby26 ruby27"
+
+RUBY_FAKEGEM_EXTRADOC="README.md AUTHORS CONTRIBUTERS"
+
+RUBY_FAKEGEM_EXTRAINSTALL="data"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Yet-another-markdown-parser but fast, pure Ruby, using strict syntax definition"
+HOMEPAGE="https://kramdown.gettalong.org/"
+
+LICENSE="MIT"
+
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64"
+IUSE="latex"
+
+LATEX_DEPS="latex? ( dev-texlive/texlive-latex dev-texlive/texlive-latexextra )"
+RDEPEND+=" ${LATEX_DEPS}"
+DEPEND+=" test? (
+	${LATEX_DEPS}
+	|| ( app-text/tidy-html5 >=app-text/htmltidy-5.0.0 )
+)"
+
+ruby_add_rdepend "
+	dev-ruby/rexml
+	>=dev-ruby/rouge-1.8
+	>=dev-ruby/stringex-1.5.1
+	!!<dev-ruby/kramdown-1.17.0-r2:0"
+
+ruby_add_bdepend "doc? ( dev-ruby/rdoc )
+	test? ( >=dev-ruby/minitest-5.0 )"
+
+all_ruby_prepare() {
+	if ! use latex; then
+		# Remove latex tests. They will fail gracefully when latex isn't
+		# present at all, but not when components are missing (most
+		# notable ucs.sty).
+		sed -i -e '/latex -v/,/^  end/ s:^:#:' test/test_files.rb || die
+	fi
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:. -e "Dir['test/test_*.rb'].each{|f| require f}" || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	doman man/man1/kramdown.1
+}