dev-ruby/rack: add 1.6.6, 2.0.2

Package-Manager: Portage-2.3.5, Repoman-2.3.1

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-ruby/rack/rack-1.6.6.ebuild b/dev-ruby/rack/rack-1.6.6.ebuild
new file mode 100644
index 000000000000..bce1580b6d5f
--- /dev/null
+++ b/dev-ruby/rack/rack-1.6.6.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby21 ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="HISTORY.md KNOWN-ISSUES README.rdoc SPEC"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem eutils versionator
+
+DESCRIPTION="A modular Ruby webserver interface"
+HOMEPAGE="https://rack.github.com/"
+
+LICENSE="MIT"
+SLOT="$(get_version_component_range 1-2)"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+RUBY_PATCHES=( ${PN}-1.2.1-gentoo.patch ${PN}-1.6-rewindable-ruby23.patch )
+
+ruby_add_rdepend "virtual/ruby-ssl"
+
+# The gem has automagic dependencies over mongrel, ruby-openid,
+# memcache-client, thin, mongrel and camping; not sure if we should
+# make them dependencies at all.
+ruby_add_bdepend "test? ( dev-ruby/bacon )"
+
+# Block against versions in older slots that also try to install a binary.
+RDEPEND="${RDEPEND} !<dev-ruby/rack-1.4.5-r1:1.4 !<dev-ruby/rack-1.5.2-r4:1.5"
+
+all_ruby_prepare() {
+	# The build system tries to generate the ChangeLog from git. Create
+	# an empty file to avoid a needless dependency on git.
+	touch ChangeLog || die
+}
+
+each_ruby_test() {
+	# Since the Rakefile calls specrb directly rather than loading it, we
+	# cannot use it to launch the tests or only the currently-selected
+	# RUBY interpreter will be tested.
+	${RUBY} -S bacon -Ilib -w -a \
+		-q -t '^(?!Rack::Handler|Rack::Adapter|Rack::Session::Memcache|Rack::Server)' \
+		|| die "test failed for ${RUBY}"
+}