dev-ruby/redcarpet: add 3.4.0

Package-Manager: portage-2.3.0

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-ruby/redcarpet/redcarpet-3.4.0.ebuild b/dev-ruby/redcarpet/redcarpet-3.4.0.ebuild
new file mode 100644
index 000000000000..3015dac4b3e5
--- /dev/null
+++ b/dev-ruby/redcarpet/redcarpet-3.4.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+USE_RUBY="ruby20 ruby21 ruby22 ruby23"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOCS="README.markdown CONTRIBUTING.md CHANGELOG.md doc"
+RUBY_FAKEGEM_TASK_TEST="test:unit"
+inherit multilib ruby-fakegem
+
+SRC_URI="https://github.com/vmg/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+DESCRIPTION="A Ruby wrapper for Upskirt"
+HOMEPAGE="https://github.com/vmg/redcarpet"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE=""
+
+ruby_add_bdepend "test? ( dev-ruby/nokogiri )"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/d' -e 's/=> :compile//'  Rakefile || die
+
+	# Avoid unneeded dependency on rake-compiler
+	sed -i -e '/extensiontask/I s:^:#:' Rakefile || die
+}
+
+each_ruby_prepare() {
+	sed -i -e "s#ruby#${RUBY}#" bin/redcarpet || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/redcarpet extconf.rb || die
+}
+
+each_ruby_compile() {
+	emake V=1 -Cext/${PN}
+	cp ext/${PN}/*$(get_modname) lib || die
+}