dev-util/bpftool: drop 5.16.11

Signed-off-by: Jakov Smolić <jsmolic@gentoo.org>

2 files changed, 0 insertions, 118 deletions

diff --git a/dev-util/bpftool/Manifest b/dev-util/bpftool/Manifest
index beacc811c6a0..e406ab86b37e 100644
--- a/dev-util/bpftool/Manifest
+++ b/dev-util/bpftool/Manifest
@@ -1,4 +1,3 @@
 DIST linux-5.16.tar.xz 123114100 BLAKE2B 07a90cc640ff89e1359c06cee8c38abd33e51f9b9a89833e31a1d2750526fda4a59e8884db3c1ea63df0a37f0d3de6b5a922b014b7313d8abce20d90ac08adcb SHA512 7a257dd576bc8493595ec7d6f3c9cb6e22c772a8b2dbe735d2485c4f5c56e26a08695546e7e0f1f1cd04a533f25e829361958d4da0b98bf0ba8094dd57a85aaf
-DIST patch-5.16.11.xz 571384 BLAKE2B 233f45175ec71c69b7893caccf8bc05a67d38d83b2f86db429e48b91f6d014f5a8646a5ded7a411b4d15205dbc9efd797dd07eeba4089cde5ebac004e204f96a SHA512 df457cb78a2b9e5ee350d3f817a0663fdc09efff42c2c514faeb30252381701404ceefa10d15845f2a00b2f3c28211fbc5b0d46bfdf564b2c1cfd3dc36a6a06a
 DIST patch-5.16.14.xz 685480 BLAKE2B 5659f5fc0287ca2f8512d213ae535c82380496314b641f6f796ab5e4d6be28cbb06c1f2ae0edf86e90780b0301ff7d395e0001d08f6b8f6d83bbc2d06c74c2e5 SHA512 e6e4a5ff64fb9e0112a2688c8ceeb26425bb52d9981d34026a973e13b76891795c599ac5edbe22b57ef56bede99c44f8fe98825b3c5db8aadb359d84fbb776b2
 DIST patch-5.16.2.xz 20432 BLAKE2B 9c9f697e4dd0a78a94ac0bd361ec69683c6904d9af02da55c3001394e6a6efcc1fccd5d44747fff6ea47271b7655bd7866d161a90196cecaddde1c630ef5c425 SHA512 50d3c386e391603fbfe86780bbfa69c3a7caa83a7eea6c239af133dde3a7aa4746f4a3f1483589018d5ac27caa7ee69d869f8f64f4b5121ddab52224f5302222
diff --git a/dev-util/bpftool/bpftool-5.16.11.ebuild b/dev-util/bpftool/bpftool-5.16.11.ebuild
deleted file mode 100644
index d4a6b8926868..000000000000
--- a/dev-util/bpftool/bpftool-5.16.11.ebuild
+++ /dev/null
@@ -1,117 +0,0 @@
-# Copyright 2021-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} )
-inherit estack linux-info optfeature python-any-r1 toolchain-funcs
-
-MY_PV="${PV/_/-}"
-MY_PV="${MY_PV/-pre/-git}"
-
-DESCRIPTION="Tool for inspection and simple manipulation of eBPF programs and maps"
-HOMEPAGE="https://kernel.org/"
-
-LINUX_V="${PV:0:1}.x"
-LINUX_VER=$(ver_cut 1-2)
-LINUX_PATCH=patch-${PV}.xz
-SRC_URI="https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/${LINUX_PATCH}"
-
-LINUX_SOURCES="linux-${LINUX_VER}.tar.xz"
-SRC_URI+=" https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/${LINUX_SOURCES}"
-
-S_K="${WORKDIR}/linux-${LINUX_VER}"
-S="${S_K}/tools/bpf/bpftool"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="caps"
-
-RDEPEND="
-	sys-libs/binutils-libs:=
-	sys-libs/zlib:=
-	virtual/libelf:=
-	caps? ( sys-libs/libcap:= )
-"
-DEPEND="
-	${RDEPEND}
-	>=sys-kernel/linux-headers-5.8
-"
-BDEPEND="
-	${LINUX_PATCH+dev-util/patchutils}
-	${PYTHON_DEPS}
-	dev-python/docutils
-"
-
-CONFIG_CHECK="~DEBUG_INFO_BTF"
-
-# src_unpack and src_prepare are copied from dev-util/perf since
-# it's building from the same tarball, please keep it in sync with perf
-src_unpack() {
-	local paths=(
-		tools/bpf kernel/bpf
-		tools/{arch,build,include,lib,perf,scripts} {scripts,include,lib} "arch/*/lib"
-	)
-
-	# We expect the tar implementation to support the -j option (both
-	# GNU tar and libarchive's tar support that).
-	echo ">>> Unpacking ${LINUX_SOURCES} (${paths[*]}) to ${PWD}"
-	tar --wildcards -xpf "${DISTDIR}"/${LINUX_SOURCES} \
-		"${paths[@]/#/linux-${LINUX_VER}/}" || die
-
-	if [[ -n ${LINUX_PATCH} ]] ; then
-		eshopts_push -o noglob
-		ebegin "Filtering partial source patch"
-		filterdiff -p1 ${paths[@]/#/-i } -z "${DISTDIR}"/${LINUX_PATCH} \
-			> ${P}.patch
-		eend $? || die "filterdiff failed"
-		eshopts_pop
-	fi
-
-	local a
-	for a in ${A}; do
-		[[ ${a} == ${LINUX_SOURCES} ]] && continue
-		[[ ${a} == ${LINUX_PATCH} ]] && continue
-		unpack ${a}
-	done
-}
-
-src_prepare() {
-	default
-
-	if [[ -n ${LINUX_PATCH} ]] ; then
-		pushd "${S_K}" >/dev/null || die
-		eapply "${WORKDIR}"/${P}.patch
-		popd || die
-	fi
-
-	# dev-python/docutils installs rst2man.py, not rst2man
-	sed -i -e 's/rst2man/rst2man.py/g' Documentation/Makefile || die
-}
-
-bpftool_make() {
-	local arch=$(tc-arch-kernel)
-	tc-export AR CC LD
-
-	emake V=1 VF=1 \
-		HOSTCC="$(tc-getBUILD_CC)" HOSTLD="$(tc-getBUILD_LD)" \
-		EXTRA_CFLAGS="${CFLAGS}" ARCH="${arch}" BPFTOOL_VERSION="${MY_PV}" \
-		prefix="${EPREFIX}"/usr \
-		feature-libcap="$(usex caps 1 0)" \
-		"$@"
-}
-
-src_compile() {
-	bpftool_make
-	bpftool_make -C Documentation
-}
-
-src_install() {
-	bpftool_make DESTDIR="${D}" install
-	bpftool_make mandir="${ED}"/usr/share/man -C Documentation install
-}
-
-pkg_postinst() {
-	optfeature "clang-bpf-co-re support" sys-devel/clang[llvm_targets_BPF]
-}