dev-util/diffoscope: add 203

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 109 insertions, 0 deletions

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index 02b085518f5f..148973cba414 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,3 +1,4 @@
 DIST diffoscope-197.tar.gz 2705041 BLAKE2B 1d66462d3f1cdbba177d24d194ce14ae51274c6b60139e56724213a6b4fc0b41e6a71f9f2e250ecc7d6330186bf774470b2153801b375ffb63e8390c425e1073 SHA512 d8411ad166738b29caa28abbc10f21e0906b7b19bd5ab644db36c04b1f9c5af9f4cbdb31eb850da7249380a6774bde355f0e815f4d3cdd0df76570df9df7fd0a
 DIST diffoscope-201.tar.gz 2705733 BLAKE2B 97f74633bd990408af9ba33feb38243da22253b1f1c49a23d11cf6cc16197b3a4fdb371f01f310a2a5ee782ae89209c2f80b0956d48b0a5c5308dd6f50aba86f SHA512 a221d656a49b77f08eb884acc8bbabd1e4469ff2411d47532c0326743653b43e45a60e5fb39d841c1b835d896dbe9d08032f51f295f5399af878be18305acd52
 DIST diffoscope-202.tar.gz 2706185 BLAKE2B 11d77445d9cd4a8b2bba5f8a31a3b9e08862937af3ce3aea993603026483758d1742254629fb7541c751ab1c5213dff892b102bc625ead78fc56ce01e25aefd8 SHA512 f42ea35a492ef62740188986b25f629d4a0d62d1ee1e6d284c4251577170720ca731a7f11f387f64b68f82817f47019b3aaf236d0bb19f4c0a65d4048c5a0266
+DIST diffoscope-203.tar.gz 2706359 BLAKE2B 1570ad567dff5d187369e8437c8a589395cb97df6374290e38bc4d8be541ad3a0176152faaa9fd63e737cb6298c3265491ade21e09b5c6157f919a6598afe339 SHA512 f093a558aff93591de9a1cd395fd0c6ec3ae2b7cde3d0390836954793c53b14b35297f997ac2f4527a93ca7985a944692e14da02ec67c5f44e31c0d4721b3a73
diff --git a/dev-util/diffoscope/diffoscope-203.ebuild b/dev-util/diffoscope/diffoscope-203.ebuild
new file mode 100644
index 000000000000..ec72907f21dc
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-203.ebuild
@@ -0,0 +1,108 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+PYTHON_REQ_USE="ncurses"
+
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+
+RESTRICT="!test? ( test )"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="test? (
+		app-text/docx2txt
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)"
+RDEPEND="dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/PyPDF2[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( net-misc/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence if filemagic's magic.py breaks imports
+# of dev-python/python-magic: https://bugs.gentoo.org/716482
+RDEPEND+=" !dev-python/filemagic"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+)
+
+distutils_enable_tests pytest