dev-util/gdbus-codegen: bump to 2.54.3

Bug: https://bugs.gentoo.org/651830
Package-Manager: Portage-2.3.40, Repoman-2.3.9

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-util/gdbus-codegen/gdbus-codegen-2.54.3.ebuild b/dev-util/gdbus-codegen/gdbus-codegen-2.54.3.ebuild
new file mode 100644
index 000000000000..1ac95b47d966
--- /dev/null
+++ b/dev-util/gdbus-codegen/gdbus-codegen-2.54.3.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME_ORG_MODULE="glib"
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+PYTHON_REQ_USE="xml"
+
+inherit gnome.org distutils-r1
+
+DESCRIPTION="GDBus code and documentation generator"
+HOMEPAGE="https://www.gtk.org/"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE=""
+
+RDEPEND="${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+# To prevent circular dependencies with glib[test]
+PDEPEND=">=dev-libs/glib-${PV}:2"
+
+S="${WORKDIR}/glib-${PV}/gio/gdbus-2.0/codegen"
+
+python_prepare_all() {
+	PATCHES=(
+		"${FILESDIR}/${PN}-2.54.3-sitedir.patch"
+	)
+	distutils-r1_python_prepare_all
+
+	sed -e 's:@PYTHON@:python:' gdbus-codegen.in > gdbus-codegen || die
+	cp "${FILESDIR}/setup.py-2.32.4" setup.py || die "cp failed"
+	sed -e "s/@PV@/${PV}/" -i setup.py || die "sed setup.py failed"
+}
+
+src_test() {
+	einfo "Skipping tests. This package is tested by dev-libs/glib"
+	einfo "when merged with FEATURES=test"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all # no-op, but prevents QA warning
+	doman "${WORKDIR}/glib-${PV}/docs/reference/gio/gdbus-codegen.1"
+}