dev-util/geany: Bump to version 1.35

Use xdg eclass for having a clean environment.

Closes: https://bugs.gentoo.org/588570
Closes: https://bugs.gentoo.org/636910
Package-Manager: Portage-2.3.65, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

1 files changed, 82 insertions, 0 deletions

diff --git a/dev-util/geany/geany-1.35.ebuild b/dev-util/geany/geany-1.35.ebuild
new file mode 100644
index 000000000000..79034d53feb2
--- /dev/null
+++ b/dev-util/geany/geany-1.35.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# eutils required for strip-linguas
+inherit eutils xdg
+
+LANGS="ar ast be bg ca cs de el en_GB es et eu fa fi fr gl he hi hu id it ja kk ko lb lt mn nl nn pl pt pt_BR ro ru sk sl sr sv tr uk vi zh_CN ZH_TW"
+NOSHORTLANGS="en_GB zh_CN zh_TW"
+
+DESCRIPTION="GTK+ based fast and lightweight IDE"
+HOMEPAGE="https://www.geany.org"
+if [[ "${PV}" = 9999* ]] ; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/geany/geany.git"
+else
+	[[ "${PV}" == *_pre* ]] && inherit autotools
+	SRC_URI="https://download.geany.org/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+fi
+LICENSE="GPL-2+ HPND"
+SLOT="0"
+
+IUSE="+gtk3 +vte"
+
+RDEPEND=">=dev-libs/glib-2.32:2
+	!gtk3? (
+		>=x11-libs/gtk+-2.24:2
+		vte? ( x11-libs/vte:0 )
+	)
+	gtk3? (
+		>=x11-libs/gtk+-3.0:3
+		vte? ( x11-libs/vte:2.91 )
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	dev-util/intltool
+	sys-devel/gettext"
+
+pkg_setup() {
+	strip-linguas ${LANGS}
+}
+
+src_prepare() {
+	xdg_src_prepare #588570
+
+	# Syntax highlighting for Portage
+	sed -i -e "s:*.sh;:*.sh;*.ebuild;*.eclass;:" \
+		data/filetype_extensions.conf || die
+
+	if [[ ${PV} = *_pre* ]] || [[ ${PV} = 9999* ]] ; then
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-html-docs
+		--disable-dependency-tracking
+		$(use_enable gtk3)
+		$(use_enable vte)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	find "${ED}" \( -name '*.a' -o -name '*.la' \) -delete || die
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+}