dev-util/jenkins-bin: bump to v2.297

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-util/jenkins-bin/jenkins-bin-2.297.ebuild b/dev-util/jenkins-bin/jenkins-bin-2.297.ebuild
new file mode 100644
index 000000000000..6272140cb584
--- /dev/null
+++ b/dev-util/jenkins-bin/jenkins-bin-2.297.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit systemd
+
+DESCRIPTION="Extensible continuous integration server"
+HOMEPAGE="https://jenkins.io/"
+LICENSE="MIT"
+SRC_URI="http://mirrors.jenkins-ci.org/war/${PV}/${PN/-bin/}.war -> ${P}.war"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux"
+IUSE=""
+
+DEPEND="acct-group/jenkins
+	acct-user/jenkins"
+
+RDEPEND="acct-group/jenkins
+	acct-user/jenkins
+	media-fonts/dejavu
+	media-libs/freetype
+	!dev-util/jenkins-bin:lts
+	>=virtual/jre-1.8.0"
+
+S="${WORKDIR}"
+
+src_install() {
+	local JENKINS_DIR=/var/lib/jenkins
+
+	keepdir /var/log/jenkins ${JENKINS_DIR}/backup ${JENKINS_DIR}/home
+
+	insinto /opt/jenkins
+	newins "${DISTDIR}"/${P}.war ${PN/-bin/}.war
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}-r1.logrotate ${PN/-bin/}
+
+	newinitd "${FILESDIR}"/${PN}-r2.init jenkins
+	newconfd "${FILESDIR}"/${PN}.confd jenkins
+
+	systemd_newunit "${FILESDIR}"/${PN}-r2.service jenkins.service
+
+	fowners jenkins:jenkins /var/log/jenkins ${JENKINS_DIR} ${JENKINS_DIR}/home ${JENKINS_DIR}/backup
+}