dev-util/ragel: bump to 7.0.3

* Bump to 7.0.3 for critical big endian fix
* Similar doc dependency changes as with colm

Bug: https://bugs.gentoo.org/677070
Bug: https://bugs.gentoo.org/733426
Closes: https://bugs.gentoo.org/766039
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-util/ragel/ragel-7.0.3.ebuild b/dev-util/ragel/ragel-7.0.3.ebuild
new file mode 100644
index 000000000000..7620cc9956c6
--- /dev/null
+++ b/dev-util/ragel/ragel-7.0.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Compiles finite state machines from regular languages into executable code"
+HOMEPAGE="https://www.colm.net/open-source/ragel/"
+SRC_URI="https://www.colm.net/files/ragel/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="doc"
+
+BDEPEND="
+	doc? (
+		|| ( app-text/asciidoc dev-ruby/asciidoctor )
+		dev-texlive/texlive-latex
+		dev-python/pygments
+		media-gfx/transfig
+	)
+"
+DEPEND="~dev-util/colm-0.14.6"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+
+	# Fix hardcoded search dir
+	sed -i -e "s:\$withval/lib:\$withval/$(get_libdir):" configure.ac || die
+
+	# Allow either asciidoctor or asciidoc
+	# bug #733426
+	sed -i -e 's/(\[ASCIIDOC\], \[asciidoc\], \[asciidoc\]/S([ASCIIDOC], [asciidoc asciidoctor]/' configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-colm="${EPREFIX}/usr" \
+		$(use_enable doc manual)
+}
+
+src_install() {
+	default
+
+	insinto /usr/share/vim/vimfiles/syntax
+	doins ragel.vim
+
+	find "${ED}" -name '*.la' -delete || die
+}