dev-util/diffoscope: add 233

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 121 insertions, 0 deletions

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index 96bb603b9830..f4cc401584a2 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,2 +1,3 @@
 DIST diffoscope-229.tar.gz 3164192 BLAKE2B bee9fa1561ddcfde98cfa44cd6d66a28c636dbc7f3ec1f4895e91dfd3b66c039b68d53be0528b94c112552069886c3c81de4d9b9bc9038d183afdc9fdde6ddb9 SHA512 825c9c33f3088ba082ea3b998594445987558ee62b8b1fbfcded9b72a739faaa73908f8753b8772b3b1a8a43dbcfd52978265a18bdd92605defcd174884ccb23
 DIST diffoscope-232.tar.gz 3164825 BLAKE2B a65ff66881cf67cdfd32eb1e14bf654c152447799415f686d774f30f7d3ec61b5de8f1caf4b3551312be7f2ab93187ea145b6bf96c7790cc3792221d621cdeb3 SHA512 7b8ae407e4e1b3c5085fa26f9477b75e3918a99b2d60498a7d939f06a3018bc5f6ca417d041a39dc769ef897a189c0dfdf6d35851b945c3e28b16f290bddb630
+DIST diffoscope-233.tar.gz 3164944 BLAKE2B 87421d3c0c0a0e970c06d3f75a067be73aa753f550bacacd603e050a0155dd7c416cab755644cb6cdf668976267e01ad13473ee52f0b06637b2d545359dc102b SHA512 ae750c3aeb3e4fb40f6bd2becdb5d148af0b369cb5dea8083a0c16d2f11b7995b7ef32a42bd1c248f14782cc792daa68e3e7838789ff4bd4c2dbb532940ef480
diff --git a/dev-util/diffoscope/diffoscope-233.ebuild b/dev-util/diffoscope/diffoscope-233.ebuild
new file mode 100644
index 000000000000..a69e36d1c939
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-233.ebuild
@@ -0,0 +1,120 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/tlsh[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/pypdf[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( net-misc/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence of filemagic's magic.py breaks imports
+# of dev-python/python-magic: bug #716482
+RDEPEND+=" !dev-python/filemagic"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="
+	test? (
+		app-text/docx2txt
+		app-text/html2text
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+	tests/comparators/test_gif.py::test_has_visuals
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+
+	# Fails on ZFS
+	tests/test_main.py::test_non_unicode_filename
+
+	# Fails on (unreleased) LLVM 16 with minor difference
+	tests/comparators/test_macho.py::test_llvm_diff
+)
+
+distutils_enable_tests pytest