games-arcade/briquolo: port to EAPI 7, games.eclass--

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 24 insertions, 14 deletions

diff --git a/games-arcade/briquolo/briquolo-0.5.7.ebuild b/games-arcade/briquolo/briquolo-0.5.7.ebuild
index 07776ecc7735..fe3a911deb66 100644
--- a/games-arcade/briquolo/briquolo-0.5.7.ebuild
+++ b/games-arcade/briquolo/briquolo-0.5.7.ebuild
@@ -1,8 +1,9 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit eutils games
+EAPI=7
+
+inherit autotools desktop toolchain-funcs
 
 DESCRIPTION="Breakout with 3D representation based on OpenGL"
 HOMEPAGE="http://briquolo.free.fr/en/index.html"
@@ -13,39 +14,48 @@ SLOT="0"
 KEYWORDS="~amd64 ~x86"
 IUSE="nls"
 
-RDEPEND="virtual/opengl
+RDEPEND="
+	virtual/opengl
 	virtual/glu
 	media-libs/libsdl[joystick,sound,video]
 	media-libs/sdl-mixer
 	media-libs/sdl-ttf
 	media-libs/libpng:0
-	nls? ( virtual/libintl )"
-DEPEND="${RDEPEND}
-	nls? ( sys-devel/gettext )"
+	nls? ( virtual/libintl )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc43.patch
+	"${FILESDIR}"/${P}-libpng14.patch
+	"${FILESDIR}"/${P}-respect-AR.patch
+)
 
 src_prepare() {
-	epatch "${FILESDIR}"/${P}-gcc43.patch \
-		"${FILESDIR}"/${P}-libpng14.patch
-	# no thanks we'll take care of it.
+	default
+
+	# No thanks, we'll take care of it.
 	sed -i \
 		-e '/^SUBDIRS/s/desktop//' \
-		Makefile.in || die
+		Makefile.{in,am} || die
 	sed -i \
 		-e "/CXXFLAGS/s:-O3:${CXXFLAGS}:" \
 		-e 's:=.*share/locale:=/usr/share/locale:' \
-		configure || die
+		configure{,.ac} || die
 	sed -i \
 		-e 's:$(datadir)/locale:/usr/share/locale:' \
 		po/Makefile.in.in || die
+
+	eautoreconf
 }
 
 src_configure() {
-	egamesconf $(use_enable nls)
+	econf $(use_enable nls)
 }
 
 src_install() {
 	default
 	doicon desktop/briquolo.svg
 	make_desktop_entry briquolo Briquolo
-	prepgamesdirs
 }