games-arcade/criticalmass: EAPI6->8, misc changes

* use https for homepage
* depend on libsdl[opengl,sound,video] (doesn't launch without opengl)
* depend on zlib
* make dependency for music unconditional (generally feel audio/music
  being a broken-if-missing optfeature is questionable for games, there
  is an option to disable correctly in-game)
* tidy patches and add some bugrefs
* fix direct AR call (combined with -flags.patch)

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/games-arcade/criticalmass/criticalmass-1.0.2-r2.ebuild b/games-arcade/criticalmass/criticalmass-1.0.2-r2.ebuild
new file mode 100644
index 000000000000..550a1493e02e
--- /dev/null
+++ b/games-arcade/criticalmass/criticalmass-1.0.2-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools desktop flag-o-matic
+
+MY_P="CriticalMass-${PV}"
+
+DESCRIPTION="SDL/OpenGL space shoot'em up game"
+HOMEPAGE="https://criticalmass.sourceforge.io/"
+SRC_URI="mirror://sourceforge/criticalmass/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2+ ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	media-libs/libglvnd[X]
+	media-libs/libpng:=
+	media-libs/libsdl[opengl,sound,video]
+	media-libs/sdl-image[png]
+	media-libs/sdl-mixer[mod]
+	net-misc/curl
+	sys-libs/zlib:="
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc43.patch
+	"${FILESDIR}"/${P}-system-curl.patch
+	"${FILESDIR}"/${P}-libpng.patch
+	"${FILESDIR}"/${P}-flags.patch
+)
+
+src_prepare() {
+	default
+
+	rm -r curl || die
+	eautoreconf
+
+	append-cxxflags -std=gnu++98 #612758
+}
+
+src_install() {
+	local HTML_DOCS="Readme.html"
+	default
+
+	rm "${ED}"/usr/bin/Packer || die #247449
+
+	newicon critter.png ${PN}.png
+	make_desktop_entry critter "Critical Mass"
+}