games-arcade/netris: add patch to build with ncurses[tinfo]

- Update Debian patchset
- EAPI=7

Closes: https://bugs.gentoo.org/687992
Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Stefan Strogin <steils@gentoo.org>

1 files changed, 62 insertions, 0 deletions

diff --git a/games-arcade/netris/netris-0.52-r3.ebuild b/games-arcade/netris/netris-0.52-r3.ebuild
new file mode 100644
index 000000000000..e4533111a8b0
--- /dev/null
+++ b/games-arcade/netris/netris-0.52-r3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DEB_VER="10"
+DESCRIPTION="Classic networked version of T*tris"
+HOMEPAGE="http://www.netris.org/"
+SRC_URI="ftp://ftp.netris.org/pub/netris/${P}.tar.gz
+	mirror://debian/pool/main/n/netris/netris_${PV}-${DEB_VER}.debian.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~mips ~x86 ~x86-fbsd"
+IUSE=""
+
+DEPEND="sys-libs/ncurses:0="
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+
+	tc-export CC CXX LD AR RANLIB
+
+	eapply "${S}"/../debian/patches/[01]*
+	eapply "${FILESDIR}"/${P}-tinfo.patch
+
+	# bug #185332
+	sed -i \
+		-e '/sys\/time/ i\
+#include <sys/types.h> \
+#include <time.h>
+' \
+		-e '/netint2/ s/short/int16_t/' \
+		-e '/netint4/ s/long/int32_t/' \
+		netris.h || die
+	sed -i \
+		-e 's/volatile //g' \
+		-e '/Be more forgiving/d' \
+		-e 's/static myRandSeed/static int myRandSeed/' \
+		util.c || die
+	sed -i \
+		-e 's/\(long pauseTimeLeft\)/\1 = 0/' \
+		game.c || die
+	sed -i \
+		-e '/^CC/d' \
+		-e '/^COPT/d' \
+		-e '/^CFLAGS/d' \
+		-e 's/(LFLAGS)/(LDFLAGS) $(LFLAGS)/' \
+		Configure || die
+}
+
+src_configure() {
+	bash ./Configure -O || die
+}
+
+src_install() {
+	dobin netris sr
+	dodoc FAQ README robot_desc
+}