games-board/biloba: fix build with gcc 10

Closes: https://bugs.gentoo.org/707232
Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Alexey Sokolov <alexey+gentoo@asokolov.org>
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/games-board/biloba/biloba-0.9.3-r2.ebuild b/games-board/biloba/biloba-0.9.3-r2.ebuild
new file mode 100644
index 000000000000..a79b45bdd803
--- /dev/null
+++ b/games-board/biloba/biloba-0.9.3-r2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop xdg-utils
+
+DESCRIPTION="a board game, up to 4 players, with AI and network"
+HOMEPAGE="http://biloba.sourceforge.net/"
+SRC_URI="mirror://sourceforge/biloba/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="media-libs/libsdl:0[X,video,sound]
+	media-libs/sdl-image[png]
+	media-libs/sdl-mixer"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	# X11 headers are checked but not used, everything is done through SDL
+	"${FILESDIR}"/${P}-not-windows.patch
+	"${FILESDIR}"/${P}-no-X11-dep.patch
+	"${FILESDIR}/${P}-gcc-10.patch"
+)
+
+src_prepare() {
+	default
+
+	# "missing" file is old, and warns about --run not being supported
+	rm missing || die
+	eautoreconf
+}
+
+src_install() {
+	default
+	newicon -s 64 biloba_icon.png ${PN}.png
+	make_desktop_entry biloba Biloba
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}