proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 106 insertions, 0 deletions

diff --git a/games-board/gnubg/gnubg-1.05.000.ebuild b/games-board/gnubg/gnubg-1.05.000.ebuild
new file mode 100644
index 000000000000..90c280ab76a5
--- /dev/null
+++ b/games-board/gnubg/gnubg-1.05.000.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+inherit eutils python-single-r1 gnome2-utils games
+
+DESCRIPTION="GNU BackGammon"
+HOMEPAGE="http://www.gnubg.org/"
+SRC_URI="http://gnubg.org/media/sources/${PN}-release-${PV}-sources.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~ppc ~ppc64 x86 ~x86-fbsd"
+IUSE="cpu_flags_x86_avx gtk opengl python sqlite cpu_flags_x86_sse cpu_flags_x86_sse2 threads"
+
+RDEPEND="dev-libs/glib:2
+	media-libs/freetype:2
+	media-libs/libpng:0
+	x11-libs/cairo
+	x11-libs/pango
+	dev-db/sqlite:3
+	media-libs/libcanberra
+	dev-libs/libxml2
+	dev-libs/gmp:0
+	gtk? ( x11-libs/gtk+:2 )
+	opengl? (
+		x11-libs/gtk+:2
+		x11-libs/gtkglext
+		virtual/glu
+	)
+	sys-libs/readline:0
+	python? ( ${PYTHON_DEPS} )
+	media-fonts/dejavu
+	virtual/libintl"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+pkg_setup() {
+	games_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# use ${T} instead of /tmp for constructing credits (bug #298275)
+	sed -i -e 's:/tmp:${T}:' credits.sh || die
+	sed -i -e 's/fonts //' Makefile.in || die # handle font install ourself to fix bug #335774
+	sed -i \
+		-e '/^localedir / s#=.*$#= @localedir@#' \
+		-e '/^gnulocaledir / s#=.*$#= @localedir@#' \
+		po/Makefile.in.in || die
+	sed -i \
+		-e '/^gnubgiconsdir / s#=.*#= /usr/share#' \
+		-e '/^gnubgpixmapsdir / s#=.*#= /usr/share/pixmaps#' \
+		pixmaps/Makefile.in || die
+}
+
+src_configure() {
+	local simd=no
+	local gtk_arg=--without-gtk
+
+	if use gtk || use opengl ; then
+		gtk_arg=--with-gtk
+	fi
+	use cpu_flags_x86_sse  && simd=sse
+	use cpu_flags_x86_sse2 && simd=sse2
+	use cpu_flags_x86_avx  && simd=avx
+	egamesconf \
+		--localedir=/usr/share/locale \
+		--docdir=/usr/share/doc/${PF}/html \
+		--disable-cputest \
+		--enable-simd=${simd} \
+		${gtk_arg} \
+		$(use_enable threads) \
+		$(use_with python) \
+		$(use_with sqlite sqlite) \
+		$(use_with opengl board3d)
+}
+
+src_install() {
+	default
+	insinto "${GAMES_DATADIR}/${PN}"
+	doins ${PN}.weights *bd
+	dodir "${GAMES_DATADIR}"/${PN}/fonts
+	dosym /usr/share/fonts/dejavu/DejaVuSans.ttf "${GAMES_DATADIR}"/${PN}/fonts/Vera.ttf
+	dosym /usr/share/fonts/dejavu/DejaVuSans-Bold.ttf "${GAMES_DATADIR}"/${PN}/fonts/VeraBd.ttf
+	dosym /usr/share/fonts/dejavu/DejaVuSerif-Bold.ttf "${GAMES_DATADIR}"/${PN}/fonts/VeraSeBd.ttf
+	make_desktop_entry "gnubg -w" "GNU Backgammon"
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}