games-board/xmille: port to EAPI 7, away from epatch.eclass

* EAPI 7
* Kill epatch.eclass

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/games-board/xmille/xmille-2.0-r4.ebuild b/games-board/xmille/xmille-2.0-r4.ebuild
new file mode 100644
index 000000000000..4ca1f38b7603
--- /dev/null
+++ b/games-board/xmille/xmille-2.0-r4.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs
+
+DEB_PATCH_VER="13"
+DESCRIPTION="Mille Bournes card game"
+HOMEPAGE="http://www.milleborne.info/"
+SRC_URI="mirror://debian/pool/main/x/xmille/${PN}_${PV}.orig.tar.gz
+	mirror://debian/pool/main/x/xmille/${PN}_${PV}-${DEB_PATCH_VER}.diff.gz"
+S="${WORKDIR}/${P}.orig"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	app-text/rman
+	x11-misc/imake
+"
+RDEPEND="x11-libs/libXext"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	eapply "${WORKDIR}"/${PN}_${PV}-${DEB_PATCH_VER}.diff
+}
+
+src_configure() {
+	xmkmf || die
+}
+
+src_compile() {
+	emake -j1 \
+		AR="$(tc-getAR) clq" \
+		RANLIB="$(tc-getRANLIB)" \
+		CC="$(tc-getCC)" \
+		CDEBUGFLAGS="${CFLAGS}" \
+		EXTRA_LDOPTIONS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin xmille
+	einstalldocs
+	make_desktop_entry "${PN}" "Milles Bournes"
+	newman xmille.man xmille.6
+}