games-fps/freedm-data: version bump to 0.12.0

Closes: https://bugs.gentoo.org/697432
Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: William Breathitt Gray <vilhelm.gray@gmail.com>
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/games-fps/freedm-data/freedm-data-0.12.0.ebuild b/games-fps/freedm-data/freedm-data-0.12.0.ebuild
new file mode 100644
index 000000000000..62b8cf23423c
--- /dev/null
+++ b/games-fps/freedm-data/freedm-data-0.12.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit prefix python-any-r1 xdg
+
+DESCRIPTION="Game resources for FreeDM"
+HOMEPAGE="https://freedoom.github.io"
+SRC_URI="https://github.com/freedoom/freedoom/archive/v${PV}.tar.gz -> freedoom-${PV}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/pillow[${PYTHON_USEDEP}]')
+	app-text/asciidoc
+	games-util/deutex"
+
+S="${WORKDIR}/freedoom-${PV}"
+
+DOOMWADPATH=share/doom
+
+python_check_deps() {
+	has_version -b "dev-python/pillow[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	xdg_src_prepare
+	eapply_user
+
+	hprefixify dist/freedoom
+}
+
+src_compile() {
+	emake wads/freedm.wad
+}
+
+src_install() {
+	emake install-freedm \
+		prefix="${ED}/usr/" \
+		bindir="bin/" \
+		mandir="share/man/" \
+		waddir="${DOOMWADPATH}/"
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "FreeDM WAD file installed into ${EPREFIX}/usr/${DOOMWADPATH} directory."
+}