games-mud/powwow: bump to 1.22.22

Closes: https://bugs.gentoo.org/716584
Closes: https://bugs.gentoo.org/690452
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/games-mud/powwow/powwow-1.2.22.ebuild b/games-mud/powwow/powwow-1.2.22.ebuild
new file mode 100644
index 000000000000..68e69db45e73
--- /dev/null
+++ b/games-mud/powwow/powwow-1.2.22.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="PowWow Console MUD Client"
+HOMEPAGE="https://www.hoopajoo.net/projects/powwow.html"
+SRC_URI="https://www.hoopajoo.net/static/projects/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="sys-libs/ncurses:0="
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.2.22-linking.patch
+	"${FILESDIR}"/${PN}-1.2.22-musl-termios.patch
+)
+
+src_prepare() {
+	default
+
+	# note that that the extra, seemingly-redundant files installed are
+	# actually used by in-game help commands
+	sed -i \
+		-e "s/pkgdata_DATA = powwow.doc/pkgdata_DATA = /" \
+		Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf --includedir="${EPREFIX}"/usr/include
+}
+
+src_install() {
+	local DOCS=( Hacking powwow.doc powwow.help README.* TODO )
+	# Prepend doc/
+	DOCS=( ${DOCS[@]/#/doc\//} )
+	# Add in the root items
+	DOCS+=( ChangeLog NEWS )
+
+	default
+}