games-strategy/naev: drop 0.10.5

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 0 insertions, 108 deletions

diff --git a/games-strategy/naev/Manifest b/games-strategy/naev/Manifest
index 382934557a04..2780e2f0eb80 100644
--- a/games-strategy/naev/Manifest
+++ b/games-strategy/naev/Manifest
@@ -1,2 +1 @@
-DIST naev-0.10.5-source.tar.xz 444950676 BLAKE2B 600d153f21ca63f5e1365fd59e3e926879c8de928db769eaffb48ba0d81781d99124866a78d7170f2b92f6982d1adb0a3ddb3ad82fd072e526afe80c9df35dda SHA512 21cd876ffe39bf09f39c65d6f744fc8e9ea1fc42f45f78e2ec9950509a37c3382ef91998ae3b0e0ced60c342c80f95e7e0c6a1301f5171d150f3cce3d76d2c00
 DIST naev-0.10.6-source.tar.xz 444950320 BLAKE2B e62d51962d85372b6ca67745dfff6c7e74af93af21a0dac92c54c8e090d422ce39b9d97a5e3e5d1aa0a84283f78516494247e6dd1c075479e19eb69c8511ab2b SHA512 0a235fbd77b29eca024eae9acec42058d4c83ec4b095408f60e50772614768abde2b0c8f144405ff280347acd40b55b5ef81988db636b3fdfe19399ca3cee479
diff --git a/games-strategy/naev/naev-0.10.5.ebuild b/games-strategy/naev/naev-0.10.5.ebuild
deleted file mode 100644
index 8304486ff77d..000000000000
--- a/games-strategy/naev/naev-0.10.5.ebuild
+++ /dev/null
@@ -1,107 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( lua5-1 luajit )
-PYTHON_COMPAT=( python3_{9..11} )
-inherit lua-single meson python-any-r1 virtualx xdg
-
-DESCRIPTION="2D space trading and combat game, in a similar vein to Escape Velocity"
-HOMEPAGE="https://naev.org/"
-SRC_URI="https://github.com/naev/naev/releases/download/v${PV}/${P}-source.tar.xz"
-
-LICENSE="
-	GPL-3+
-	Apache-2.0 BSD BSD-2 CC-BY-2.0 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-3.0
-	CC-BY-SA-4.0 CC0-1.0 GPL-2+ MIT OFL-1.1 public-domain"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc"
-REQUIRED_USE="${LUA_REQUIRED_USE}"
-
-# dlopen: libglvnd
-RDEPEND="
-	${LUA_DEPS}
-	dev-games/physfs
-	dev-libs/libpcre2:=
-	dev-libs/libunibreak:=
-	dev-libs/libxml2
-	media-libs/freetype:2
-	media-libs/libglvnd
-	media-libs/libsdl2[joystick,opengl,video]
-	media-libs/libvorbis
-	media-libs/openal
-	media-libs/sdl2-image[png,webp]
-	net-libs/enet:1.3=
-	sci-libs/cholmod
-	sci-libs/cxsparse
-	sci-libs/openblas
-	sci-libs/suitesparse
-	sci-mathematics/glpk:=
-	virtual/libintl"
-DEPEND="
-	${RDEPEND}
-	test? (
-		dev-games/physfs[zip]
-		media-libs/libsdl2[X]
-	)"
-BDEPEND="
-	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
-	sys-devel/gettext
-	doc? (
-		app-doc/doxygen
-		dev-lua/ldoc
-		media-gfx/graphviz
-	)
-	test? (
-		media-libs/mesa[llvm]
-		x11-base/xorg-server[-minimal]
-	)"
-
-python_check_deps() {
-	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	lua-single_pkg_setup
-	python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	# use eclass' generated lua.pc first rather than as fallback
-	sed -i "s/'lua51'/'lua'/" meson.build || die
-
-	# don't probe OpenGL for tests (avoids sandbox violations, bug #829369),
-	# mesa[llvm] should ensure software rendering will work
-	sed -i "/subdir('glcheck')/d" test/meson.build || die
-}
-
-src_configure() {
-	local emesonargs=(
-		$(meson_feature doc docs_c)
-		$(meson_feature doc docs_lua)
-		$(meson_feature lua_single_target_luajit luajit)
-	)
-
-	meson_src_configure
-}
-
-src_test() {
-	virtx meson_src_test
-}
-
-src_install() {
-	local DOCS=( CHANGELOG Readme.md )
-	meson_src_install
-
-	if use doc; then
-		dodir /usr/share/doc/${PF}/html
-		mv "${ED}"/usr/{doc/naev/{c,lua},share/doc/${PF}/html} || die
-		rm -r "${ED}"/usr/doc || die
-	fi
-
-	rm -r "${ED}"/usr/share/doc/naev || die
-}