games-util/lutris: add 0.5.13_beta1

Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

3 files changed, 89 insertions, 4 deletions

diff --git a/games-util/lutris/Manifest b/games-util/lutris/Manifest
index 24686ff14ed8..8084898a5a1d 100644
--- a/games-util/lutris/Manifest
+++ b/games-util/lutris/Manifest
@@ -1 +1,2 @@
+DIST lutris-0.5.13_beta1.tar.gz 1330507 BLAKE2B dd0c38776658efd5ef85f170a89c141de51821492b7edb29c3b85cdb3332f590941fe141ee6e71e87615f467b10af24bf422bd6fd21307998fcfde9eeddf2727 SHA512 83f3c212c1f4290568bce911e4d40aa778d513f444dc6ddf42870242d9c70ae79fbb141d81e144aa8cd918a7fa794c815cd1254b1864e0154fb73d4e1e2aa5bd
 DIST lutris_0.5.12.tar.xz 2252220 BLAKE2B 511de660e32ab8961d951d5777ef21a343ab46736cc74f2202721f3280cfab39cac0a8a7003db4eaa48265f4af2d598c1011ce45988815624accda18663a2f00 SHA512 032f9b628bc829bfde347c8137cad80a28cad16651baf461a344045d23c0f19d860627a042225de16046d14d45e03e5ebf7a3a82010128c114e2a0f429a02bf9
diff --git a/games-util/lutris/lutris-0.5.13_beta1.ebuild b/games-util/lutris/lutris-0.5.13_beta1.ebuild
new file mode 100644
index 000000000000..43d4ec1636e1
--- /dev/null
+++ b/games-util/lutris/lutris-0.5.13_beta1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="sqlite,threads(+)"
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 optfeature virtualx xdg
+
+DESCRIPTION="An open source gaming platform for GNU/Linux"
+HOMEPAGE="https://lutris.net/"
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/lutris/lutris.git"
+	inherit git-r3
+else
+	if [[ ${PV} == *_beta* ]] ; then
+		SRC_URI="https://github.com/lutris/lutris/archive/refs/tags/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+		S="${WORKDIR}"/${P/_/-}
+	else
+		SRC_URI="https://lutris.net/releases/${P/-/_}.tar.xz"
+		S="${WORKDIR}/${PN}"
+		KEYWORDS="~amd64 ~x86"
+	fi
+fi
+
+LICENSE="GPL-3+ CC0-1.0"
+SLOT="0"
+
+RDEPEND="
+	app-arch/cabextract
+	app-arch/p7zip
+	app-arch/unzip
+	$(python_gen_cond_dep '
+		dev-python/certifi[${PYTHON_USEDEP}]
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/distro[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/pypresence[${PYTHON_USEDEP}]
+		dev-python/python-evdev[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/protobuf-python[${PYTHON_USEDEP}]
+		dev-python/moddb[${PYTHON_USEDEP}]
+	')
+	media-sound/fluid-soundfont
+	|| (
+		net-libs/webkit-gtk:4[introspection]
+		net-libs/webkit-gtk:4.1[introspection]
+	)
+	x11-apps/mesa-progs
+	x11-apps/xgamma
+	x11-apps/xrandr
+	x11-libs/gtk+:3[introspection]
+	x11-libs/gdk-pixbuf[jpeg]
+"
+
+distutils_enable_tests pytest
+
+DOCS=( AUTHORS README.rst docs/installers.rst docs/steam.rst )
+
+python_test() {
+	virtx epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	python_fix_shebang "${ED}/usr/share/lutris/bin/lutris-wrapper" #740048
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "running MS Windows games through wine+DXVK/proton or other Vulkan games (plus ICD for your hardware)" media-libs/vulkan-loader
+
+	# Quote README.rst
+	elog ""
+	elog "Lutris installations are fully automated through scripts, which can"
+	elog "be written in either JSON or YAML. The scripting syntax is described"
+	elog "in ${EROOT}/usr/share/doc/${PF}/installers.rst.bz2, and is also"
+	elog "available online at lutris.net."
+}
diff --git a/games-util/lutris/lutris-9999.ebuild b/games-util/lutris/lutris-9999.ebuild
index 0b268cfd6c78..43d4ec1636e1 100644
--- a/games-util/lutris/lutris-9999.ebuild
+++ b/games-util/lutris/lutris-9999.ebuild
@@ -45,6 +45,7 @@ RDEPEND="
 		dev-python/python-evdev[${PYTHON_USEDEP}]
 		dev-python/pyyaml[${PYTHON_USEDEP}]
 		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/protobuf-python[${PYTHON_USEDEP}]
 		dev-python/moddb[${PYTHON_USEDEP}]
 	')
 	media-sound/fluid-soundfont
@@ -63,10 +64,6 @@ distutils_enable_tests pytest
 
 DOCS=( AUTHORS README.rst docs/installers.rst docs/steam.rst )
 
-PATCHES=(
-	"${FILESDIR}/${PN}-0.5.13-webkit-gtk-4-1.patch"
-)
-
 python_test() {
 	virtx epytest
 }