gnome-base/gnome-light: bump to 3.26.2

Also fix P_RELEASE, which seems to have meant to carry the major.minor
of the GNOME release cycle, but was just "2" instead. Use eapi7-ver
and do it properly.

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 59 insertions, 0 deletions

diff --git a/gnome-base/gnome-light/gnome-light-3.26.2.ebuild b/gnome-base/gnome-light/gnome-light-3.26.2.ebuild
new file mode 100644
index 000000000000..96a74b14c9c8
--- /dev/null
+++ b/gnome-base/gnome-light/gnome-light-3.26.2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eapi7-ver
+
+P_RELEASE="$(ver_cut 1-2)"
+
+DESCRIPTION="Meta package for GNOME-Light, merge this package to install"
+HOMEPAGE="https://www.gnome.org/"
+LICENSE="metapackage"
+SLOT="2.0"
+IUSE="cups +gnome-shell"
+
+# when unmasking for an arch
+# double check none of the deps are still masked !
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86"
+
+# XXX: Note to developers:
+# This is a wrapper for the 'light' GNOME 3 desktop, and should only consist of
+# the bare minimum of libs/apps needed. It is basically gnome-base/gnome without
+# any apps, but shouldn't be used by users unless they know what they are doing.
+RDEPEND="!gnome-base/gnome
+	>=gnome-base/gnome-core-libs-${PV}[cups?]
+
+	>=gnome-base/gnome-session-3.26.1
+	>=gnome-base/gnome-settings-daemon-${PV}[cups?]
+	>=gnome-base/gnome-control-center-${PV}[cups?]
+
+	>=gnome-base/nautilus-${PV}
+
+	gnome-shell? (
+		>=x11-wm/mutter-${PV}
+		>=gnome-base/gnome-shell-${PV} )
+
+	>=x11-themes/adwaita-icon-theme-${P_RELEASE}
+	>=x11-themes/gnome-themes-standard-3.22.3
+	>=x11-themes/gnome-backgrounds-${PV}
+
+	>=x11-terms/gnome-terminal-${PV}
+"
+DEPEND=""
+PDEPEND=">=gnome-base/gvfs-1.34.1"
+S="${WORKDIR}"
+
+pkg_pretend() {
+	if ! use gnome-shell; then
+		# Users probably want to use e16, sawfish, etc
+		ewarn "You're not installing GNOME Shell"
+		ewarn "You will have to install and manage a window manager by yourself"
+	fi
+}
+
+pkg_postinst() {
+	# Remember people where to find our project information
+	elog "Please remember to look at https://wiki.gentoo.org/wiki/Project:GNOME"
+	elog "for information about the project and documentation."
+}