gnome-extra/gnome-logs: version bump 3.20.1 → 3.22.1

Fix dependencies for unittests. Add missing gsettings-desktop-schemas dependency.

Package-Manager: portage-2.3.1

1 files changed, 53 insertions, 0 deletions

diff --git a/gnome-extra/gnome-logs/gnome-logs-3.22.1.ebuild b/gnome-extra/gnome-logs/gnome-logs-3.22.1.ebuild
new file mode 100644
index 000000000000..bc11cb5290ed
--- /dev/null
+++ b/gnome-extra/gnome-logs/gnome-logs-3.22.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 virtualx
+
+DESCRIPTION="Log messages and event viewer"
+HOMEPAGE="https://wiki.gnome.org/Apps/Logs"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=dev-libs/glib-2.43.90:2
+	gnome-base/gsettings-desktop-schemas
+	sys-apps/systemd:=
+	>=x11-libs/gtk+-3.19.3:3
+"
+DEPEND="${RDEPEND}
+	~app-text/docbook-xml-dtd-4.3
+	app-text/yelp-tools
+	dev-libs/appstream-glib
+	dev-libs/libxslt
+	>=dev-util/intltool-0.50
+	gnome-base/gnome-common
+	virtual/pkgconfig
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--enable-man \
+		$(use_enable test tests)
+}
+
+src_test() {
+	virtx emake check
+}