gnome-extra/gnome-boxes: Version bump to 45_rc

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32603
Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 121 insertions, 0 deletions

diff --git a/gnome-extra/gnome-boxes/Manifest b/gnome-extra/gnome-boxes/Manifest
index 1503eff5b447..19e82fe105f8 100644
--- a/gnome-extra/gnome-boxes/Manifest
+++ b/gnome-extra/gnome-boxes/Manifest
@@ -1 +1,2 @@
 DIST gnome-boxes-44.2.tar.xz 1239344 BLAKE2B 69b2c387f3482f41450df89ed742d754c68f119c02b4aa7401b019a28e21494d07b6402fe2ae2e5fb59f4c292e7246ef8a5eb240bb586359368c3dbab93b83ca SHA512 08e40cd45a4bdc3ba82bfd0a5f4065e56685c43343d6e745f51a5a8043b402a1eb6b6396193600d89d30b2791cb4e8718194ca1b83b7be954b83b5d939eed948
+DIST gnome-boxes-45.rc.tar.xz 1261380 BLAKE2B 2467ba9ccd5810cbeab79a9c4908a29c2cf67ed76b878c74b1e1c14f023908d6466b97275e9c91ddcae6293ab7344daa3ee03963deac4741efa689d67c4d9cf9 SHA512 741d5c4a6c5f2cf66a8e8ca791dd489bfd45c67c58fb81b3221f7bf5bf70c51452e30b63a222b9b705fcc5ee4a8504329dc23b3c97820df95acc346910f5cd1e
diff --git a/gnome-extra/gnome-boxes/gnome-boxes-45_rc.ebuild b/gnome-extra/gnome-boxes/gnome-boxes-45_rc.ebuild
new file mode 100644
index 000000000000..f94eec3e74bf
--- /dev/null
+++ b/gnome-extra/gnome-boxes/gnome-boxes-45_rc.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils linux-info meson readme.gentoo-r1 vala xdg
+
+DESCRIPTION="Simple GNOME application to access remote or virtual systems"
+HOMEPAGE="https://gnomeboxes.org"
+
+LICENSE="LGPL-2+ CC-BY-2.0"
+SLOT="0"
+
+KEYWORDS="~amd64"
+
+# FIXME: qemu probably needs to depend on spice[smartcard] directly with USE=spice
+# FIXME: Check over libvirt USE=libvirtd,qemu and the smartcard/usbredir requirements
+# Technically vala itself still ships a libsoup vapi, but that may change, and
+# it should be better to use the .vapi from the same libsoup version
+DEPEND="
+	>=app-arch/libarchive-3.0.0:=
+	>=dev-libs/glib-2.52:2
+	>=x11-libs/gtk+-3.24.1:3
+	>=gui-libs/libhandy-1.5.0:1
+	>=sys-libs/libosinfo-1.10.0-r1
+	net-libs/libsoup:3.0
+	virtual/libusb:1
+	>=app-emulation/libvirt-glib-4.0.0
+	>=dev-libs/libxml2-2.7.8:2
+	>=net-misc/spice-gtk-0.32[gtk3(+),smartcard,usbredir]
+	>=net-libs/webkit-gtk-2.38.0:4.1
+
+	>=dev-libs/gobject-introspection-1.56:=
+	>=dev-libs/libgudev-165:=
+" # gobject-introspection needed for libovf subproject
+# These are called via exec():
+# - sys-fs/mtools mcopy for unattended file copying for files that libarchive doesn't support
+# - app-cdr/cdrtools mkisofs is needed for unattended installer secondary disk image creation
+# - app-emulation/libguestfs virt-sysprep is used for VM cloing, if not there, it logs debug and doesn't function
+# - sys-apps/policycoreutils restorecon is used for checking selinux context
+# - app-emulation/libvirt virsh used for various checks (and we need the library anyways)
+# - sys-auth/polkit used for making all libvirt system disks readable via "pkexec
+#   chmod a+r" that aren't already readable to the user (libvirt system importer)
+# - app-emulation/qemu qemu-img used to convert image to QCOW2 format during copy
+RDEPEND="${DEPEND}
+	app-cdr/cdrtools
+	app-misc/tracker-miners:3[iso]
+	app-emulation/spice[smartcard]
+	>=app-emulation/libvirt-0.9.3[libvirtd,qemu]
+	>=app-emulation/qemu-1.3.1[spice,smartcard,usbredir]
+	sys-fs/mtools
+	sys-auth/polkit
+"
+# This is only needed for creating the .vapi file, but gnome-boxes needs it
+BDEPEND="
+	$(vala_depend)
+	sys-libs/libosinfo[vala]
+	app-crypt/libsecret[vala]
+	net-libs/libsoup:3.0[vala]
+	app-emulation/libvirt-glib[vala]
+	net-misc/spice-gtk[vala]
+	x11-libs/vte:2.91[vala]
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="Before running gnome-boxes for local VMs, you will need to load the KVM modules.
+If you have an Intel Processor, run:
+# modprobe kvm-intel
+
+If you have an AMD Processor, run:
+# modprobe kvm-amd"
+
+pkg_pretend() {
+	linux-info_get_any_version
+
+	if linux_config_exists; then
+		if ! { linux_chkconfig_present KVM_AMD || \
+			linux_chkconfig_present KVM_INTEL; }; then
+			ewarn "You need KVM support in your kernel to use GNOME Boxes local VM support!"
+		fi
+	fi
+}
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddistributor_name=Gentoo
+		-Ddistributor_version=${PVR}
+		-Dinstalled_tests=false
+		-Dflatpak=false
+		-Dprofile=default
+		-Duefi=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}