gnome-extra/cinnamon-settings-daemon: 5.0.4 version bump

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 96 insertions, 0 deletions

diff --git a/gnome-extra/cinnamon-settings-daemon/Manifest b/gnome-extra/cinnamon-settings-daemon/Manifest
index d715127e86a7..abd01e5ca998 100644
--- a/gnome-extra/cinnamon-settings-daemon/Manifest
+++ b/gnome-extra/cinnamon-settings-daemon/Manifest
@@ -1,2 +1,3 @@
 DIST cinnamon-settings-daemon-4.8.5.tar.gz 662123 BLAKE2B b3ddd72e55c10c2cacc6dd29145e381395bd2ef68db7082a0770bb3eb647964041ed023d4a8357f2adcf5e8c9f8f713bac837809ed5926cc0434c2dc3e5c90ad SHA512 4a1d128b3f6faf3e2c13420d3569d4fd8cfaa1798ba5cf83fcb692662b9888d22f9f4bfb6fe18af59d0632583a2730a07e3ab48cca12c357b2d318d205fd7d0a
 DIST cinnamon-settings-daemon-5.0.3.tar.gz 663648 BLAKE2B 78067cc11b0a8e77f8bc0a0a942430dbee31e9b8f1a857b9f10b7c16982c0d5e64267e91d35bbd1d66391d328e35efc536d953eee00b2b4b3c6d8c6c28052601 SHA512 ab44c5c157d5a37b35a88f89ba76254ade3f7dfdfaaa7ea7a09aabb49dce3c8f7d789d5d136b2a629c37483d2098ec957bfd07f930d786475ac1bf3973f4d56f
+DIST cinnamon-settings-daemon-5.0.4.tar.gz 663647 BLAKE2B 459ca8b407291e7a84742b75a272a621d05ef1929ec76dd913af477629db862429165cec26a5985c75f81ce8eaddccc6b74cfa882106784bbfb40e015a21bab8 SHA512 861847fb238ae53fdb31c55ab7f8475f3cad9b48a5dd3611e5ea05129e16b44cc48b3ff5d38c2fdcc3669191f952bf194b6bcba80816fb4daee9e91d85b1c781
diff --git a/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-5.0.4.ebuild b/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-5.0.4.ebuild
new file mode 100644
index 000000000000..6e71b246e5ee
--- /dev/null
+++ b/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-5.0.4.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit meson gnome2-utils python-any-r1 xdg
+
+DESCRIPTION="Cinnamon's settings daemon"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-settings-daemon"
+SRC_URI="https://github.com/linuxmint/cinnamon-settings-daemon/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+colord cups input_devices_wacom smartcard systemd"
+
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	dev-libs/libgudev:=
+	>=gnome-base/libgnomekbd-3.6
+	>=gnome-extra/cinnamon-desktop-5.0:0=
+	media-libs/fontconfig
+	>=media-libs/lcms-2.2:2
+	media-libs/libcanberra:0=[gtk3,pulseaudio]
+	>=media-sound/pulseaudio-0.9.16[glib]
+	>=sys-apps/dbus-1.1.2
+	dev-libs/dbus-glib
+	>=sys-auth/polkit-0.97
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.14.0:3
+	>=x11-libs/libnotify-0.7.3:0=
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	>=x11-libs/libxklavier-5.0
+	>=sys-power/upower-0.9.11
+
+	colord? ( >=x11-misc/colord-0.1.27:= )
+	cups? (
+		>=net-print/cups-1.4[dbus]
+		app-admin/system-config-printer
+		net-print/cups-pk-helper )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7
+		>=gnome-base/librsvg-2.36.2
+		x11-drivers/xf86-input-wacom
+		x11-libs/libXtst )
+	smartcard? ( >=dev-libs/nss-3.11.2 )
+	systemd? ( sys-apps/systemd:0= )
+	!systemd? ( sys-auth/elogind:0= )
+"
+DEPEND="
+	${RDEPEND}
+	dev-libs/libxml2:2
+	x11-base/xorg-proto
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+	dev-util/gdbus-codegen
+	>=dev-util/intltool-0.37.1
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	python_fix_shebang install-scripts
+}
+
+src_configure() {
+	# gudev not optional on Linux platforms
+	local emesonargs=(
+		-Duse_gudev=enabled
+		-Duse_polkit=enabled
+		-Duse_logind=enabled
+		$(meson_feature colord use_color)
+		$(meson_feature cups use_cups)
+		$(meson_feature smartcard use_smartcard)
+		$(meson_feature input_devices_wacom use_wacom)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}