gnome-extra/gnome-shell-extension-applications-overview-tooltip: Support gnome 44

Signed-off-by: Pacho Ramos <pacho@gentoo.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/gnome-extra/gnome-shell-extension-applications-overview-tooltip/gnome-shell-extension-applications-overview-tooltip-16-r1.ebuild b/gnome-extra/gnome-shell-extension-applications-overview-tooltip/gnome-shell-extension-applications-overview-tooltip-16-r1.ebuild
new file mode 100644
index 000000000000..5b6b473b9deb
--- /dev/null
+++ b/gnome-extra/gnome-shell-extension-applications-overview-tooltip/gnome-shell-extension-applications-overview-tooltip-16-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome2-utils
+
+DESCRIPTION="Show tooltip with full name and description"
+HOMEPAGE="https://github.com/RaphaelRochet/applications-overview-tooltip"
+SRC_URI="https://github.com/RaphaelRochet/applications-overview-tooltip/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+# https://github.com/RaphaelRochet/applications-overview-tooltip/issues/7
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	app-eselect/eselect-gnome-shell-extensions
+	>=gnome-base/gnome-shell-40
+"
+DEPEND=""
+BDEPEND=""
+
+S="${WORKDIR}/${P/gnome-shell-extension-}"
+extension_uuid="applications-overview-tooltip@RaphaelRochet"
+
+src_prepare() {
+	default
+	# https://github.com/RaphaelRochet/applications-overview-tooltip/issues/29
+	sed -i -e 's/"43"/"43", "44"/' metadata.json
+}
+
+src_install() {
+	einstalldocs
+	insinto /usr/share/glib-2.0/schemas
+	doins schemas/*.xml
+	rm -rf README.md schemas || die
+	insinto /usr/share/gnome-shell/extensions/"${extension_uuid}"
+	doins -r *
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}