gui-libs/neatvnc: Version bump to 0.7.0

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

4 files changed, 72 insertions, 3 deletions

diff --git a/gui-libs/neatvnc/Manifest b/gui-libs/neatvnc/Manifest
index c15694e3f9b5..fbd029cfd3d7 100644
--- a/gui-libs/neatvnc/Manifest
+++ b/gui-libs/neatvnc/Manifest
@@ -1 +1,2 @@
 DIST neatvnc-0.6.0.tar.gz 578084 BLAKE2B 63a064054a61996bd09064e4684d6d4e836290b9c0a097138a8dbefc3615b8d22f1932caef3b147bf3a12fa14ef808d314016d53411e2d461e775e1a34522e15 SHA512 7fc38aa36faba227e37ec241b874f7c83e7bb912b22cb1f2198622a0bb3145661111bf58b3f9e376b0d03f04b667ba94f2e60f7f5e886c141178a874c820ea91
+DIST neatvnc-0.7.0.tar.gz 660642 BLAKE2B ae14f3d35839ae141d6cce760c118f6605b66c16e3d8e6fae4606deaa63adacab13d3c8dbc001a3937f4f1f6f9c908607176ea36a914d39a126730c77f3470c7 SHA512 79abf2f6d5676e1d8dc9f70a341ae0247ae20dd95f8724d27c667ae42d45c8b5f4de2321c0dad6278e0eebefbcda0a512da917fa6e5def801f938875bdab18d0
diff --git a/gui-libs/neatvnc/metadata.xml b/gui-libs/neatvnc/metadata.xml
index 6063f9cd5636..109d0f5191a0 100644
--- a/gui-libs/neatvnc/metadata.xml
+++ b/gui-libs/neatvnc/metadata.xml
@@ -8,8 +8,9 @@
 	<use>
 		<flag name="examples">Build and install examples</flag>
 		<flag name="gbm">Enable support for the Generic Buffer Manager (gbm)</flag>
-		<flag name="h264">Enable fast encodings</flag>
-		<flag name="jpeg">Enable H.264 encoding</flag>
+		<flag name="h264">Enable H.264 encoding</flag>
+		<flag name="jpeg">Enable JPEG compression</flag>
 		<flag name="tracing">Trace kernel and memory calls</flag>
+		<flag name="websockets">Enable websockets support</flag>
 	</use>
 </pkgmetadata>
diff --git a/gui-libs/neatvnc/neatvnc-0.7.0.ebuild b/gui-libs/neatvnc/neatvnc-0.7.0.ebuild
new file mode 100644
index 000000000000..e5e117a78e2b
--- /dev/null
+++ b/gui-libs/neatvnc/neatvnc-0.7.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Liberally licensed VNC server library with a clean interface"
+HOMEPAGE="https://github.com/any1/neatvnc/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/any1/neatvnc.git"
+else
+	SRC_URI="https://github.com/any1/neatvnc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~loong ~riscv ~x86"
+fi
+
+LICENSE="ISC"
+SLOT="0"
+IUSE="examples gbm h264 jpeg ssl test tracing websockets"
+REQUIRED_USE="h264? ( gbm )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	=dev-libs/aml-0.3*
+	sys-libs/zlib
+	x11-libs/pixman
+	gbm? ( media-libs/mesa )
+	h264? (
+		media-video/ffmpeg:=
+		x11-libs/libdrm
+	)
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	ssl? ( net-libs/gnutls:= )
+	tracing? ( dev-util/systemtap )
+	websockets? (
+		dev-libs/gmp:=
+		dev-libs/nettle:=[gmp]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	x11-libs/libdrm
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use examples)
+		$(meson_use test tests)
+		$(meson_feature jpeg)
+		$(meson_feature ssl tls)
+		$(meson_feature websockets nettle)
+		$(meson_use tracing systemtap)
+		$(meson_feature gbm)
+		$(meson_feature h264)
+	)
+	meson_src_configure
+}
diff --git a/gui-libs/neatvnc/neatvnc-9999.ebuild b/gui-libs/neatvnc/neatvnc-9999.ebuild
index a07844f06217..e5e117a78e2b 100644
--- a/gui-libs/neatvnc/neatvnc-9999.ebuild
+++ b/gui-libs/neatvnc/neatvnc-9999.ebuild
@@ -18,7 +18,7 @@ fi
 
 LICENSE="ISC"
 SLOT="0"
-IUSE="examples gbm h264 jpeg ssl test tracing"
+IUSE="examples gbm h264 jpeg ssl test tracing websockets"
 REQUIRED_USE="h264? ( gbm )"
 RESTRICT="!test? ( test )"
 
@@ -34,6 +34,10 @@ RDEPEND="
 	jpeg? ( media-libs/libjpeg-turbo:= )
 	ssl? ( net-libs/gnutls:= )
 	tracing? ( dev-util/systemtap )
+	websockets? (
+		dev-libs/gmp:=
+		dev-libs/nettle:=[gmp]
+	)
 "
 DEPEND="
 	${RDEPEND}
@@ -49,6 +53,7 @@ src_configure() {
 		$(meson_use test tests)
 		$(meson_feature jpeg)
 		$(meson_feature ssl tls)
+		$(meson_feature websockets nettle)
 		$(meson_use tracing systemtap)
 		$(meson_feature gbm)
 		$(meson_feature h264)