kde-apps/dolphin-plugins-git: 20.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/kde-apps/dolphin-plugins-git/Manifest b/kde-apps/dolphin-plugins-git/Manifest
index 56d9c906a4c3..6dbf959ee8b7 100644
--- a/kde-apps/dolphin-plugins-git/Manifest
+++ b/kde-apps/dolphin-plugins-git/Manifest
@@ -1 +1,2 @@
 DIST dolphin-plugins-20.08.3.tar.xz 230272 BLAKE2B 1978ffebe88d95350cac0892c56e127507b6ddd6d5675bca8f420990552e20ff271e6f5742a2bdeff685c82464e70177ac83e5e9368547eb175a3e8133d77624 SHA512 2010be567ef025375caac92e90c0259faea1eb58bdbc55e441e42a10af68b6313391707a7f6b6b10285ba80dcbdee92468fa5088970eb98d4ea8afea145976d9
+DIST dolphin-plugins-20.12.0.tar.xz 236436 BLAKE2B ed8b525c8934b3f1b41f53a9c22a1db211632b58a015e93d507eb46943920fc22e245b81e360bf30d75fe066a2a6ed36857bd3b446faf07b32132ef5755c1eb1 SHA512 a5ed5ae83ba8d2f0af5521f2219191acee2693aae656d829d425a8f9d7d21857511fdda3730dcc88e910ab5a2b6b76817a324498cffa390be3fa616bc57dd106
diff --git a/kde-apps/dolphin-plugins-git/dolphin-plugins-git-20.12.0.ebuild b/kde-apps/dolphin-plugins-git/dolphin-plugins-git-20.12.0.ebuild
new file mode 100644
index 000000000000..33a133476f47
--- /dev/null
+++ b/kde-apps/dolphin-plugins-git/dolphin-plugins-git-20.12.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="git"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.75.0
+QTMIN=5.15.1
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for Git integration"
+HOMEPAGE="https://apps.kde.org/en/dolphin_plugins"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	!kde-apps/dolphin-plugins:5
+	dev-vcs/git
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_bogus_dep Qt5 DBus
+	ecm_punt_bogus_dep KF5 Solid
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_bogus_dep Qt5 Network
+	ecm_punt_bogus_dep KF5 XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}