kde-apps/kig: 21.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/kde-apps/kig/Manifest b/kde-apps/kig/Manifest
index 27d64f05ad93..cde8d9cf60fd 100644
--- a/kde-apps/kig/Manifest
+++ b/kde-apps/kig/Manifest
@@ -1 +1,2 @@
 DIST kig-21.08.3.tar.xz 3175388 BLAKE2B 7c515b80a7334680e40777cc73971d3cd9f595f038c02f9862929cbdfd88d4d8b287a3694561c1b3ab8fc6cc5225e47bd68c7668e5e89dccb00d5d4596422a2f SHA512 73d348b81be9eea6cfef9b7e266a86a115aa1d05236ca55b4639782465b0b4550d041645fdf1d37908ad109f6d093ffe21b1a1f73fda6b9b590473ef803088f2
+DIST kig-21.12.0.tar.xz 3175116 BLAKE2B c29eec5d06cc948c50b5794e92fe1612462f496a703b6c9bbdf5767261be567fa6eae2d9033c20c46f02099f2c24d654d2c96c985fa6c57930ae66c3399ab1df SHA512 327c38310e378e001e91b4a40ba7cd40a2c9efbe458baf12cdb9238415582b1ccc463b1e0c8786f35aee8fab834e3cc7e1898338274e016fa90608dd1cc8e0b7
diff --git a/kde-apps/kig/kig-21.12.0.ebuild b/kde-apps/kig/kig-21.12.0.ebuild
new file mode 100644
index 000000000000..333ed3b8f50b
--- /dev/null
+++ b/kde-apps/kig/kig-21.12.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PYTHON_COMPAT=( python3_{8..10} )
+KFMIN=5.88.0
+QTMIN=5.15.2
+inherit python-single-r1 ecm kde.org
+
+DESCRIPTION="KDE Interactive Geometry tool"
+HOMEPAGE="https://apps.kde.org/kig/ https://edu.kde.org/kig/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="geogebra scripting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	geogebra? ( >=dev-qt/qtxmlpatterns-${QTMIN}:5 )
+	scripting? (
+		$(python_gen_cond_dep '
+			>=dev-libs/boost-1.70:=[python,${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-20.08.70-cmake-boostpython.patch )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_prepare() {
+	ecm_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBOOSTPYTHON_VERSION_MAJOR_MINOR=${EPYTHON}
+		$(cmake_use_find_package geogebra Qt5XmlPatterns)
+		$(cmake_use_find_package scripting Boost)
+	)
+
+	ecm_src_configure
+}