kde-apps/kwave: 22.08.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index 5f7721c1352d..a9b57c509fa2 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-22.04.3.tar.xz 6956708 BLAKE2B 3b7d883f13d5f98136f6e41366ada978af742910c672b70e8b55f5fae4c2a312e0524daf3800d4b5d0f7aa599143bbbc459a87f97364183fdbbe4867e78e4a58 SHA512 7dd6e3ef76371d750619e6d2c8c55cea2c3e727b1a6f552ecc4a9318181488af99eb7a01912407945a74b5c7c80c66dcee01a5facf2743e9aea43d0391b7ba2d
 DIST kwave-22.08.1.tar.xz 6956384 BLAKE2B 159f4bb5ab948bab184347b0af1d9610a5a97818255b45158294e29327d7cff27843e8ff4cb3381e8a2d1ae2f8387b3e47756acf288e341b4edc776b08acfb75 SHA512 e5a9d9adc05b21d7f20e0d8b3debbff1c9c2012d738f7efab40674a2da0dc2c40dc0e020a93ce03c686cc7cb629ed2af847cf56324ce3aaed46a15ca85e74244
+DIST kwave-22.08.2.tar.xz 6956288 BLAKE2B 1f035925848f9cbf13a0ed50c529079cb76aa621ce248546677d8e8d495991075c576509ac1b1371e5374ecd62e5cc8d9c119c85c0c147d106ec1f4ffe840093 SHA512 106fef1739ea5fca126692c3aeb4eb0cd5d0fd058c7c14783cc7386b16063f9cdc3977f92850cef6d284b5c909ab3ebe25e9843c8d737d15f5d61501530e7772
diff --git a/kde-apps/kwave/kwave-22.08.2.ebuild b/kde-apps/kwave/kwave-22.08.2.ebuild
new file mode 100644
index 000000000000..bc386a23d764
--- /dev/null
+++ b/kde-apps/kwave/kwave-22.08.2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.96.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/kwave/"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3:=
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac:=[cxx] )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-libs/libpulse )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}