kde-apps/kwave: 24.02.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index 98da00045f80..a030056c72e7 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-23.08.4.tar.xz 6982484 BLAKE2B adf1d7acf2b6177a32c149cbec945fc124952c75b921e741c8a3ab17f164724e99b953ca75f232bc9ddb1dd5437cdc3df5a792b96be43b3e04861b8a43d6812c SHA512 5507924468ba912efc8d6f57a21291b9a2caf2b444ed35ad5c69011e54ea1b7706f2a0f1bbadccb68c6988745ce610466525c8d989483197c15df43e27875ea6
 DIST kwave-23.08.5.tar.xz 6983092 BLAKE2B 44dcfc18659cba78ed9a7b0b155d1362e4122ef5b245fea64e039b74c1a1fda020814ba9d35530e2abdf65cfbc72c8c6bf93fe1c44266c198e5c19ffbed9d1b4 SHA512 e80b0d79b652419b0b09b10ab1613ca823e9ae9ed4d9112e29bf91d4841e8bdf84c54e52483245922798623a2727f554540646aa873077ec8b83c4c5343824c1
+DIST kwave-24.02.0.tar.xz 6979816 BLAKE2B 6b3fad98141d730d08d66e30a101ac56187ed4404587b12eb99b75789fbb0ef0d640f331779b8b4401819ade6ba3166a313dacd6c48ffa3dfb22c797d73e94b8 SHA512 699669420e8151367eabcc1a5d13ff13fe40c81ea9d784addaf1b57aa8656d3c7bc08b56db5ef5c9a4153abc3de9cc1f0c5b3637ecedf5bcd6f95c24066e9eb4
diff --git a/kde-apps/kwave/kwave-24.02.0.ebuild b/kde-apps/kwave/kwave-24.02.0.ebuild
new file mode 100644
index 000000000000..323d9080f514
--- /dev/null
+++ b/kde-apps/kwave/kwave-24.02.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.113.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/kwave/"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3:=
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac:=[cxx] )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-libs/libpulse )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}