kde-frameworks/breeze-icons-rcc: 5.246.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.246.0.ebuild b/kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.246.0.ebuild
new file mode 100644
index 000000000000..b5298ac78635
--- /dev/null
+++ b/kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.246.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="breeze-icons"
+PVCUT=$(ver_cut 1-2)
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake frameworks.kde.org python-any-r1
+
+DESCRIPTION="Breeze SVG icon theme binary resource"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-qt/qtbase:6[test] )"
+RDEPEND="!kde-frameworks/${PN}:5"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	dev-qt/qtbase:6
+	>=kde-frameworks/extra-cmake-modules-${PVCUT}:*
+	test? ( app-misc/fdupes )
+"
+
+python_check_deps() {
+	python_has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use test || cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=ON
+		-DSKIP_INSTALL_ICONS=ON
+	)
+	cmake_src_configure
+}