kde-frameworks: Add KDE Frameworks 5.34

Package-Manager: Portage-2.3.5, Repoman-2.3.1

1 files changed, 50 insertions, 0 deletions

diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-5.34.0.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-5.34.0.ebuild
new file mode 100644
index 000000000000..4d6180f9ec19
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-5.34.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils kde5
+
+DESCRIPTION="Library for extracting file metadata"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="epub exif ffmpeg libav office pdf taglib"
+
+RDEPEND="
+	$(add_frameworks_dep ki18n)
+	$(add_qt_dep qtxml)
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? (
+		libav? ( media-video/libav:= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	office? ( $(add_frameworks_dep karchive) )
+	pdf? ( app-text/poppler[qt5] )
+	taglib? ( media-libs/taglib )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package epub EPub)
+		$(cmake-utils_use_find_package exif Exiv2)
+		$(cmake-utils_use_find_package ffmpeg FFmpeg)
+		$(cmake-utils_use_find_package office KF5Archive)
+		$(cmake-utils_use_find_package pdf Poppler)
+		$(cmake-utils_use_find_package taglib Taglib)
+	)
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	if ! has_version app-text/catdoc || ! has_version dev-libs/libxls; then
+		elog "To get additional features, optional runtime dependencies may be installed:"
+		optfeature "indexing of Microsoft Word or Powerpoint files" app-text/catdoc
+		optfeature "indexing of Microsoft Excel files" dev-libs/libxls
+	fi
+}