kde-plasma/plasma-firewall: 5.27.11 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 66 insertions, 0 deletions

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index 40c970f775bb..20141b57299f 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.27.10.tar.xz 363288 BLAKE2B abebad4476e270ec5da39a4a8791382fe287d058e0e8bd2fe381204300cf41213adaa8125ca1c585d457ab969beadcd6122119798ae6c8bda0ad6660d2d14217 SHA512 350d44e26b6a9100b3f6ac9022b2e653f2ff55ec62f8efbef7b747eac006d8a0eb7182f8161a587cafadc07d5126fc0ea439e0624e578911ddba718fc99856d4
+DIST plasma-firewall-5.27.11.tar.xz 362988 BLAKE2B 484e853f4a8c61823e2a235fe5d5e40b6861c04044ca5058b8e866d9a9d9cb072b8a64c2c1b8a950f1604acc85dd27c38314735db2b6e4f59e8fb9085eda0ea8 SHA512 9c6a41448ef83a1c464e1e10441ae811bc898afc451b821fbd46141df4ffe1ad395692c420ce02dd5618197a307fa2729dbe8f0f703c1a64b14068f6c018ba7b
 DIST plasma-firewall-6.0.1.tar.xz 368664 BLAKE2B 13444325d835c49fb50f6262b2d097a122b921189bc3b1013283e3dde60bd686c38810dfa22b87a9d34894fb3e5aa7161609cb38dd0431fb4a84298c713bbf70 SHA512 c767e117699a5987b35f08112097e8ca91034e4104518f0d0a57f87f85106652867c1947901b6c66a7cc4e05e47a69ef34bb971bd5a180501f635ad2cee0a865
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.27.11.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.27.11.ebuild
new file mode 100644
index 000000000000..56b7b7ca39b7
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.27.11.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+PYTHON_COMPAT=( python3_{10..12} )
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}