kde-plasma/plasma-workspace: Various 5.27.8 backports

OSD: Fix size calculation for progress value
KDE-bug: https://bugs.kde.org/show_bug.cgi?id=469576

Also adding upstream commits 062a3735, c703882c, ddddbd96:
shell: avoid potential crash when previous window is gone before returning focus
PanelView: also restore previous window when status changes to `ActiveStatus`
PanelView: clear previous focus when status changes to ActiveStatus

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 231 insertions, 0 deletions

diff --git a/kde-plasma/plasma-workspace/Manifest b/kde-plasma/plasma-workspace/Manifest
index 5954b66b31f8..8821f648f0d1 100644
--- a/kde-plasma/plasma-workspace/Manifest
+++ b/kde-plasma/plasma-workspace/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-workspace-5.27.6.tar.xz 19459172 BLAKE2B d1b1a1ccb8a76149882ed49ed662a561a04963d154ada7259665f8d228af17004dfb464ee684c5c14402166261ec176e322642f736f7fd55f233d31f11bcf256 SHA512 090c65ecb1664d5e55d52ff7a11e6402a2b9bb7a31c99fe3406c2c4111aada6102aaf3f5a110c6a13223e88ee164caf209d859fcb6823b638ca42bcbb683984d
+DIST plasma-workspace-5.27.7-patchset-1.tar.xz 2816 BLAKE2B 167142839927092b35d52407c81522d6eddfd49f563df2312512fd465f2959c4d7f97a6bdf2ea2cecaa575c84f219d7e418cfff89adfd1af92289a7b3a61d102 SHA512 2db99d64dd806a4193983a0dc17208b6c477dda065b58b03801ea32faf38815c692d326518fdffa0949aa107a447cd9cd043d9e53b3ad13eca723829ee8adfdc
 DIST plasma-workspace-5.27.7.tar.xz 19465984 BLAKE2B e6b1a4aac29798f6aa2f18b1877d00e33ae6e8ca2daa5999b34a1d29bc149c870486f2e4021e6308d7e848df3a0af83f2bc0298f1def4100f17e4b69c6a7a0ae SHA512 7359d087cb94280ed0c191b0328b8aa2ec42460a6eb057a06bae0de3abcfa8e3cd7c374b47a4b1d08b56fc292892bac4c0f501527574e2c799c3d4c87591892f
diff --git a/kde-plasma/plasma-workspace/plasma-workspace-5.27.7-r1.ebuild b/kde-plasma/plasma-workspace/plasma-workspace-5.27.7-r1.ebuild
new file mode 100644
index 000000000000..b7dcff58831c
--- /dev/null
+++ b/kde-plasma/plasma-workspace/plasma-workspace-5.27.7-r1.ebuild
@@ -0,0 +1,230 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm plasma.kde.org
+
+DESCRIPTION="KDE Plasma workspace"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${P}-patchset-1.tar.xz"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="appstream +calendar +fontconfig geolocation gps +policykit
+screencast +semantic-desktop telemetry +wallpaper-metadata"
+
+REQUIRED_USE="gps? ( geolocation )"
+RESTRICT="test"
+
+# kde-frameworks/kwindowsystem[X]: Uses KX11Extras
+# slot op: various private QtWaylandClient headers
+COMMON_DEPEND="
+	dev-libs/icu:=
+	>=dev-libs/wayland-1.15
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5=[jpeg,libinput]
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwayland-${QTMIN}:5=
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kactivities-stats-${KFMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kinit-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kpeople-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kunitconversion-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5[X]
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/prison-${KFMIN}:5[qml]
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-plasma/breeze-${PVCUT}:5
+	>=kde-plasma/kscreenlocker-${PVCUT}:5
+	>=kde-plasma/kwin-${PVCUT}:5
+	>=kde-plasma/layer-shell-qt-${PVCUT}:5
+	>=kde-plasma/libkscreen-${PVCUT}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	>=media-libs/phonon-4.11.0
+	sci-libs/libqalculate:=
+	sys-libs/zlib
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libxcb
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/xcb-util
+	appstream? ( dev-libs/appstream[qt5] )
+	calendar? ( >=kde-frameworks/kholidays-${KFMIN}:5 )
+	fontconfig? (
+		>=dev-qt/qtprintsupport-${QTMIN}:5
+		media-libs/fontconfig
+		x11-libs/libXft
+		x11-libs/xcb-util-image
+	)
+	geolocation? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
+	gps? ( sci-geosciences/gpsd )
+	policykit? (
+		sys-auth/polkit-qt
+		virtual/libcrypt:=
+	)
+	screencast? (
+		>=dev-qt/qtgui-${QTMIN}:5=[egl]
+		>=kde-plasma/kpipewire-${PVCUT}:5
+		media-libs/libglvnd
+		>=media-video/pipewire-0.3:=
+		x11-libs/libdrm
+	)
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+	telemetry? ( dev-libs/kuserfeedback:5 )
+	wallpaper-metadata? ( kde-apps/libkexiv2:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/plasma-wayland-protocols-1.6.0
+	>=dev-libs/wayland-protocols-1.31
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	x11-base/xorg-proto
+	fontconfig? ( x11-libs/libXrender )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<kde-plasma/breeze-5.22.90:5
+	!<kde-plasma/plasma-desktop-5.27.0:5
+	app-text/iso-codes
+	>=dev-qt/qdbus-${QTMIN}:*
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtpaths-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5[widgets]
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	kde-apps/kio-extras:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/kquickcharts-${KFMIN}:5
+	>=kde-plasma/milou-${PVCUT}:5
+	>=kde-plasma/plasma-integration-${PVCUT}:5
+	sys-apps/dbus
+	x11-apps/xmessage
+	x11-apps/xprop
+	x11-apps/xrdb
+	x11-apps/xsetroot
+	policykit? ( sys-apps/accountsservice )
+"
+BDEPEND="
+	>=dev-qt/qtwaylandscanner-${QTMIN}:5
+	>=dev-util/wayland-scanner-1.19.0
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	virtual/pkgconfig
+"
+PDEPEND=">=kde-plasma/kde-cli-tools-${PVCUT}:5"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.24.80-split-libkworkspace.patch" # downstream
+	"${FILESDIR}/${PN}-5.22.5-krunner-cwd-at-home.patch" # TODO upstream: KDE-bug 432975, bug 767478
+	"${WORKDIR}/${P}-patchset-1" # KDE-bug 469576
+)
+
+src_prepare() {
+	ecm_src_prepare
+
+	cmake_comment_add_subdirectory libkworkspace
+	# delete colliding libkworkspace translations
+	find po -type f -name "*po" -and -name "libkworkspace*" -delete || die
+
+	# TODO: try to get a build switch upstreamed
+	if ! use screencast; then
+		ecm_punt_bogus_dep KPipeWire
+		sed -e "s/^pkg_check_modules.*PipeWire/#&/" -i CMakeLists.txt || die
+	fi
+
+	# TODO: try to get a build switch upstreamed
+	if use geolocation; then
+		use gps || sed -e "s/^pkg_check_modules.*LIBGPS/#&/" \
+			-i dataengines/geolocation/CMakeLists.txt || die
+	fi
+
+	if ! use policykit; then
+		cmake_run_in kcms cmake_comment_add_subdirectory users
+	fi
+
+	if ! use fontconfig; then
+		ecm_punt_bogus_dep XCB IMAGE
+		sed -e "s/check_X11_lib(Xft)/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_xembed-sni-proxy=OFF
+		-DGLIBC_LOCALE_GEN=$(usex policykit)
+		$(cmake_use_find_package appstream AppStreamQt)
+		$(cmake_use_find_package calendar KF5Holidays)
+		$(cmake_use_find_package fontconfig Fontconfig)
+		$(cmake_use_find_package geolocation KF5NetworkManagerQt)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# default startup and shutdown scripts
+	insinto /etc/xdg/plasma-workspace/env
+	doins "${FILESDIR}"/10-agent-startup.sh
+
+	insinto /etc/xdg/plasma-workspace/shutdown
+	doins "${FILESDIR}"/10-agent-shutdown.sh
+	fperms +x /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
+	elog "edit ${EPREFIX}/etc/xdg/plasma-workspace/env/10-agent-startup.sh"
+	elog "and ${EPREFIX}/etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
+}