mail-filter/postforward: Version bump to 1.1.1

Copy of the 1.1.0 ebuild, update copyright & EAPI, and tweak to remove
double-negative new_src_dir check.

Closes: https://bugs.gentoo.org/687858
Closes: https://github.com/gentoo/gentoo/pull/12239
Signed-off-by: Philippe Chaintreuil <gentoo_bugs_peep@parallaxshift.com>
Package-Manager: Portage-2.3.66, Repoman-2.3.11
Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/mail-filter/postforward/postforward-1.1.1.ebuild b/mail-filter/postforward/postforward-1.1.1.ebuild
new file mode 100644
index 000000000000..f9f2be8689ca
--- /dev/null
+++ b/mail-filter/postforward/postforward-1.1.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit golang-build
+
+DESCRIPTION="Postfix Sender Rewriting Scheme forwarding agent"
+EGO_PN="${PN}"
+SRC_URI="https://github.com/zoni/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+HOMEPAGE="https://github.com/zoni/postforward"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	dev-lang/go:0"
+RDEPEND="
+	mail-filter/postsrsd"
+
+PATCHES=( "${FILESDIR}/${PN}_apply-sendmail-path.patch" )
+
+src_prepare() {
+	default
+
+	# Dynamically fix EPREFIX lines made by ${PN}_apply-sendmail-path.patch
+	sed -i -e "s/@GENTOO_PORTAGE_EPREFIX@/${EPREFIX}/" *.go || die
+
+	# go build assumes files will be in src dir, but
+	# source files are in root in this package, so move
+	# them.
+	local new_src_dir="${S}/src/${EGO_PN}"
+	# Freak out if there's already something there because
+	# it means the package has changed and we'll need to
+	# adjust to it.
+	[[ -e "${new_src_dir}" ]] && die "${new_src_dir} already exists"
+	mkdir -p "${new_src_dir}" || die
+	mv *.go "${new_src_dir}" || die
+}
+
+# Standard golang-build src_install complains about pkg not
+# existing, so we go custom.
+src_install() {
+	einstalldocs
+	dosbin "${PN}"
+}