proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 73 insertions, 0 deletions

diff --git a/media-gfx/enblend/enblend-4.1.1-r1.ebuild b/media-gfx/enblend/enblend-4.1.1-r1.ebuild
new file mode 100644
index 000000000000..20e28328a046
--- /dev/null
+++ b/media-gfx/enblend/enblend-4.1.1-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils
+
+MY_P="${PN}-enfuse-${PV/_rc/rc}"
+
+DESCRIPTION="Image Blending with Multiresolution Splines"
+HOMEPAGE="http://enblend.sourceforge.net/"
+SRC_URI="mirror://sourceforge/enblend/${MY_P}.tar.gz"
+
+LICENSE="GPL-2 VIGRA"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug doc gpu image-cache openmp"
+
+REQUIRED_USE="openmp? ( !image-cache )"
+
+RDEPEND="
+	media-libs/glew
+	=media-libs/lcms-2*
+	>=media-libs/libpng-1.2.43:0=
+	>=media-libs/openexr-1.0:=
+	media-libs/plotutils[X]
+	media-libs/tiff
+	>=media-libs/vigra-1.8.0
+	sci-libs/gsl
+	virtual/jpeg:0=
+	debug? ( dev-libs/dmalloc )
+	gpu? ( media-libs/freeglut )"
+DEPEND="${RDEPEND}
+	>=dev-libs/boost-1.31.0:=
+	virtual/pkgconfig
+	doc? (
+		media-gfx/imagemagick
+		media-gfx/transfig
+		sci-visualization/gnuplot[gd]
+		virtual/latex-base
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	sed -i -e "/CXX_FLAGS/s:-O3::g" CMakeLists.txt || die
+	sed -i -e "s:doc/enblend:doc/${P}:" doc/CMakeLists.txt || die
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_CXX_FLAGS_RELEASE=""
+		$(cmake-utils_use_enable debug DMALLOC)
+		$(cmake-utils_use doc DOC)
+		$(cmake-utils_use_enable image-cache IMAGECACHE)
+		$(cmake-utils_use_enable openmp)
+		$(cmake-utils_use_enable gpu)
+	)
+	CMAKE_BUILD_TYPE="Release"
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	# forcing -j1 as every parallel compilation process needs about 1 GB RAM.
+	cmake-utils_src_compile -j1
+}
+
+src_install() {
+	local DOCS=( AUTHORS ChangeLog NEWS README )
+	cmake-utils_src_install
+}