summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJeroen Roovers <jer@gentoo.org>2020-01-05 14:00:58 +0100
committerJeroen Roovers <jer@gentoo.org>2020-01-05 14:01:36 +0100
commitf60583ee9980bff47f123b16208ac6689b50f5a5 (patch)
tree357e668af917b62172add086b95c9c265cd62596 /media-gfx/imv/imv-4.0.1-r1.ebuild
parentmedia-gfx/imv: Update live ebuild. (diff)
downloadgentoo-f60583ee9980bff47f123b16208ac6689b50f5a5.tar.gz
gentoo-f60583ee9980bff47f123b16208ac6689b50f5a5.tar.bz2
gentoo-f60583ee9980bff47f123b16208ac6689b50f5a5.zip
media-gfx/imv: Depend on x11-libs/libxcb x11-libs/libxkbcommon
Package-Manager: Portage-2.3.84, Repoman-2.3.20 Signed-off-by: Jeroen Roovers <jer@gentoo.org>
Diffstat (limited to 'media-gfx/imv/imv-4.0.1-r1.ebuild')
-rw-r--r--media-gfx/imv/imv-4.0.1-r1.ebuild90
1 files changed, 90 insertions, 0 deletions
diff --git a/media-gfx/imv/imv-4.0.1-r1.ebuild b/media-gfx/imv/imv-4.0.1-r1.ebuild
new file mode 100644
index 00000000000..dab63717b9c
--- /dev/null
+++ b/media-gfx/imv/imv-4.0.1-r1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs xdg-utils
+
+DESCRIPTION="Minimal image viewer designed for tiling window manager users"
+HOMEPAGE="https://github.com/eXeC64/imv"
+SRC_URI="https://github.com/eXeC64/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT-with-advertising"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="X +freeimage jpeg png +svg test tiff wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+ || ( X wayland )
+"
+
+RDEPEND="
+ !sys-apps/renameutils
+ media-libs/fontconfig
+ media-libs/libsdl2
+ media-libs/sdl2-ttf
+ X? (
+ x11-libs/libX11
+ x11-libs/libxcb
+ x11-libs/libxkbcommon
+ x11-libs/pango
+ )
+ freeimage? ( media-libs/freeimage )
+ jpeg? ( media-libs/libjpeg-turbo )
+ png? ( media-libs/libpng )
+ svg? ( gnome-base/librsvg )
+ tiff? ( media-libs/tiff )
+ wayland? ( dev-libs/wayland )
+"
+BDEPEND="
+ app-text/asciidoc
+ test? ( dev-util/cmocka )
+"
+DEPEND="
+ ${RDEPEND}
+"
+
+src_prepare() {
+ default
+ sed -i -e 's|pkg-config|$(PKG_CONFIG)|g' Makefile || die
+}
+
+src_configure() {
+ tc-export PKG_CONFIG
+ local WINDOWS
+ if use X; then
+ if ! use wayland; then
+ WINDOWS=x11
+ else
+ WINDOWS=all
+ fi
+ else
+ if use wayland; then
+ WINDOWS=wayland
+ fi
+ fi
+
+ BACKENDS=(
+ BACKEND_FREEIMAGE=$(usex freeimage)
+ BACKEND_JPEG=$(usex jpeg)
+ BACKEND_LIBPNG=$(usex png)
+ BACKEND_LIBRSVG=$(usex svg)
+ BACKEND_LIBTIFF=$(usex tiff)
+ WINDOWS=${WINDOWS}
+ )
+}
+
+src_compile() {
+ emake ${BACKENDS[@]}
+}
+
+src_install() {
+ emake ${BACKENDS[@]} DESTDIR="${D}" install
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+}