media-gfx/jpeg2ps: Update ebuild for EAPI 7.

Closes: https://bugs.gentoo.org/335526
Closes: https://bugs.gentoo.org/468664
Bug: https://bugs.gentoo.org/697288
Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Ulrich Müller <ulm@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/media-gfx/jpeg2ps/jpeg2ps-1.9-r2.ebuild b/media-gfx/jpeg2ps/jpeg2ps-1.9-r2.ebuild
new file mode 100644
index 000000000000..7d2bc418a0d0
--- /dev/null
+++ b/media-gfx/jpeg2ps/jpeg2ps-1.9-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs readme.gentoo-r1
+
+DESCRIPTION="Convert JPEG images to Postscript using a wrapper"
+HOMEPAGE="https://web.archive.org/web/20131003144811/http://www.pdflib.com/download/free-software/jpeg2ps/"
+SRC_URI="https://web.archive.org/web/20131003165952/http://www.pdflib.com/fileadmin/pdflib/products/more/${PN}/${P}.tar.gz"
+
+LICENSE="free-noncomm"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="metric"
+
+PATCHES=("${FILESDIR}"/${P}-include.diff)
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		LD="$(tc-getCC)" \
+		CFLAGS="-c ${CFLAGS} $(usex metric "-DA4" "")" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin jpeg2ps
+	doman jpeg2ps.1
+	dodoc jpeg2ps.txt
+
+	if use metric; then
+		DOC_CONTENTS="By default, this installation of jpeg2ps will generate
+			A4 size output.  You can force letter output with
+			\n\tjpeg2ps -p letter file.jpg > file.ps"
+	else
+		DOC_CONTENTS="By default, this installation of jpeg2ps will generate
+			letter size output.  You can force A4 output with
+			\n\tjpeg2ps -p a4 file.jpg > file.ps"
+	fi
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}