media-gfx/digikam: Fix build with >=kde-apps/akonadi-contacts-23.04.0

Upstream commit 5b4ba173f6a84a8be1131b1523dc42df95171ec7

Closes: https://bugs.gentoo.org/904976
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

3 files changed, 181 insertions, 1 deletions

diff --git a/media-gfx/digikam/digikam-7.10.0-r1.ebuild b/media-gfx/digikam/digikam-7.10.0-r1.ebuild
new file mode 100644
index 000000000000..a87c4c457218
--- /dev/null
+++ b/media-gfx/digikam/digikam-7.10.0-r1.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=5.88.0
+QTMIN=5.15.5
+inherit ecm kde.org toolchain-funcs
+
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	if [[ ${PV} =~ beta[0-9]$ ]]; then
+		SRC_URI="mirror://kde/unstable/${PN}/"
+	else
+		SRC_URI="mirror://kde/stable/${PN}/${PV}/"
+	fi
+	SRC_URI+="digiKam-${PV/_/-}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${PV/_/-}"
+fi
+
+DESCRIPTION="Digital photo management application"
+HOMEPAGE="https://www.digikam.org/"
+
+LICENSE="GPL-2"
+SLOT="5"
+IUSE="addressbook calendar gphoto2 heif +imagemagick +lensfun marble mysql opengl openmp +panorama scanner semantic-desktop X"
+
+# bug 366505
+RESTRICT="test"
+
+COMMON_DEPEND="
+	dev-libs/expat
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5[-gles2-only]
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5[mysql?]
+	>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=dev-qt/qtxmlpatterns-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=media-gfx/exiv2-0.27:=[xmp]
+	media-libs/lcms:2
+	media-libs/libjpeg-turbo:=
+	media-libs/liblqr
+	media-libs/libpng:=
+	>=media-libs/opencv-3.3.0:=[contrib,contribdnn,features2d]
+	media-libs/tiff:=
+	addressbook? (
+		>=kde-apps/akonadi-contacts-19.04.3:5
+		>=kde-frameworks/kcontacts-${KFMIN}:5
+	)
+	calendar? ( >=kde-frameworks/kcalendarcore-${KFMIN}:5 )
+	gphoto2? ( media-libs/libgphoto2:= )
+	heif? (
+		media-libs/libheif:=
+		media-libs/x265:=
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	lensfun? ( media-libs/lensfun )
+	marble? (
+		>=dev-qt/qtconcurrent-${QTMIN}:5
+		>=kde-apps/marble-19.04.3:5
+		>=kde-frameworks/kbookmarks-${KFMIN}:5
+	)
+	opengl? (
+		>=dev-qt/qtopengl-${QTMIN}:5
+		virtual/opengl
+	)
+	panorama? ( >=kde-frameworks/threadweaver-${KFMIN}:5 )
+	scanner? ( >=kde-apps/libksane-19.04.3:5 )
+	semantic-desktop? ( >=kde-frameworks/kfilemetadata-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	dev-cpp/eigen:3
+	dev-libs/boost
+	addressbook? ( >=kde-apps/akonadi-19.04.3:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	mysql? ( virtual/mysql[server(+)] )
+	panorama? ( media-gfx/hugin )
+"
+BDEPEND="
+	sys-devel/gettext
+	panorama? (
+		sys-devel/bison
+		sys-devel/flex
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-7.8.0-cmake.patch"
+	"${FILESDIR}/${PN}-7.9.0-akonadi-23.04.patch" # bug 904976
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	ecm_pkg_pretend
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	ecm_pkg_setup
+}
+
+# FIXME: Unbundle libraw (libs/rawengine/libraw)
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=OFF # bug 698192
+		-DENABLE_APPSTYLES=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Jasper=ON
+		-DENABLE_MEDIAPLAYER=OFF # bug 758641, last-rited
+		-DENABLE_QWEBENGINE=ON
+		-DENABLE_AKONADICONTACTSUPPORT=$(usex addressbook)
+		$(cmake_use_find_package calendar KF5CalendarCore)
+		$(cmake_use_find_package gphoto2 Gphoto2)
+		$(cmake_use_find_package heif Libheif)
+		$(cmake_use_find_package imagemagick ImageMagick)
+		$(cmake_use_find_package lensfun LensFun)
+		$(cmake_use_find_package marble Marble)
+		-DENABLE_MYSQLSUPPORT=$(usex mysql)
+		-DENABLE_INTERNALMYSQL=$(usex mysql)
+		$(cmake_use_find_package opengl OpenGL)
+		$(cmake_use_find_package panorama KF5ThreadWeaver)
+		$(cmake_use_find_package scanner KF5Sane)
+		-DENABLE_KFILEMETADATASUPPORT=$(usex semantic-desktop)
+		$(cmake_use_find_package X X11)
+	)
+
+	ecm_src_configure
+}
diff --git a/media-gfx/digikam/digikam-7.9.0-r1.ebuild b/media-gfx/digikam/digikam-7.9.0-r1.ebuild
index 72affdeb5cb8..8dceca760739 100644
--- a/media-gfx/digikam/digikam-7.9.0-r1.ebuild
+++ b/media-gfx/digikam/digikam-7.9.0-r1.ebuild
@@ -96,6 +96,7 @@ COMMON_DEPEND="
 DEPEND="${COMMON_DEPEND}
 	dev-cpp/eigen:3
 	dev-libs/boost
+	addressbook? ( >=kde-apps/akonadi-19.04.3:5 )
 "
 RDEPEND="${COMMON_DEPEND}
 	mysql? ( virtual/mysql[server(+)] )
@@ -109,7 +110,10 @@ BDEPEND="
 	)
 "
 
-PATCHES=( "${FILESDIR}/${PN}-7.8.0-cmake.patch" )
+PATCHES=(
+	"${FILESDIR}/${PN}-7.8.0-cmake.patch"
+	"${FILESDIR}/${P}-akonadi-23.04.patch" # bug 904976
+)
 
 pkg_pretend() {
 	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
diff --git a/media-gfx/digikam/files/digikam-7.9.0-akonadi-23.04.patch b/media-gfx/digikam/files/digikam-7.9.0-akonadi-23.04.patch
new file mode 100644
index 000000000000..d9b46a7966f0
--- /dev/null
+++ b/media-gfx/digikam/files/digikam-7.9.0-akonadi-23.04.patch
@@ -0,0 +1,27 @@
+From 5b4ba173f6a84a8be1131b1523dc42df95171ec7 Mon Sep 17 00:00:00 2001
+From: Antonio Rojas <arojas@archlinux.org>
+Date: Thu, 20 Apr 2023 17:49:44 +0200
+Subject: [PATCH] Fix build with akonadi 23.04
+
+In KDE PIM 23.04 the KF5:: targets have been renamed to KPim5::
+While the KF5:: targets are kept for backwards compatibility, they no longer recursively include other KF5:: targets.
+We need to search for Akonadi explicitly so that the KF5::AkonadiCore target is defined.
+---
+ core/CMakeLists.txt | 1 +
+ 1 file changed, 1 insertion(+)
+
+diff --git a/core/CMakeLists.txt b/core/CMakeLists.txt
+index 4cb33d2f9e6..610033425cd 100644
+--- a/core/CMakeLists.txt
++++ b/core/CMakeLists.txt
+@@ -124,6 +124,7 @@ if(ENABLE_AKONADICONTACTSUPPORT)
+ 
+     find_package(KF5 ${AKONADI_MIN_VERSION} QUIET REQUIRED
+                  OPTIONAL_COMPONENTS
++                 Akonadi
+                  AkonadiContact         # For KDE Mail Contacts support.
+                  Contacts               # API for contacts/address book data.
+     )
+-- 
+GitLab
+