media-gfx/fontforge: add 20230101

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 110 insertions, 0 deletions

diff --git a/media-gfx/fontforge/Manifest b/media-gfx/fontforge/Manifest
index b4152e8113e0..b350e2764565 100644
--- a/media-gfx/fontforge/Manifest
+++ b/media-gfx/fontforge/Manifest
@@ -1 +1,2 @@
 DIST fontforge-20220308.tar.xz 13719032 BLAKE2B 66939a77014b086b95ea21c3af2a2c910c19ebba000d50e514000667a6b193f5a90fc55b6046793811cac3a7330c479973746ac09041f21b0237047105f4d305 SHA512 9975cffec8aa47bcb8c22405bea544cd263dc939b253e8fba2fbaa3b90a60e05b98eaf58365db8ae854d1fff8e641866a7e2e027003ae03a77104d6650dafb6c
+DIST fontforge-20230101.tar.xz 13761728 BLAKE2B 69e79e7c5d8b551a847ba8706157b0f559ae2a85f61711f50e4855eb6a177bbfb25de2650caf9bc8a7dd1d6af074ca5063519b2f3c151d8c784c4750c6ddc1d8 SHA512 7684a2824d5199e230d2e0a654c2119cef422a57b64e6dd75afde6ba623abed6581f596fd5b7509e03f3b3ad3cf69629aafd4c85aeda64fa91a9e1ab88c9b418
diff --git a/media-gfx/fontforge/fontforge-20230101.ebuild b/media-gfx/fontforge/fontforge-20230101.ebuild
new file mode 100644
index 000000000000..fefc0183c007
--- /dev/null
+++ b/media-gfx/fontforge/fontforge-20230101.ebuild
@@ -0,0 +1,109 @@
+# Copyright 2004-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit python-single-r1 xdg cmake
+
+DESCRIPTION="postscript font editor and converter"
+HOMEPAGE="https://fontforge.org/"
+SRC_URI="https://github.com/fontforge/fontforge/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="BSD GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc truetype-debugger gif gtk jpeg png +python readline test tiff svg woff2 X"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-libs/glib-2.67:2
+	dev-libs/libltdl:0
+	dev-libs/libxml2:2=
+	>=media-libs/freetype-2.3.7:2=
+	gif? ( media-libs/giflib:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	png? ( media-libs/libpng:= )
+	tiff? ( media-libs/tiff:= )
+	truetype-debugger? ( >=media-libs/freetype-2.3.8:2[fontforge,-bindist(-)] )
+	gtk? ( >=x11-libs/gtk+-3.10:3 )
+	!gtk? (
+		X? (
+			>=x11-libs/cairo-1.6:0=
+			>=x11-libs/pango-1.10:0=[X]
+			x11-libs/libX11:=
+			x11-libs/libXi:=
+		)
+	)
+	python? ( ${PYTHON_DEPS} )
+	readline? ( sys-libs/readline:0= )
+	woff2? ( media-libs/woff2:0= )
+"
+DEPEND="${RDEPEND}
+	!gtk? ( X? ( x11-base/xorg-proto ) )
+"
+BDEPEND="
+	sys-devel/gettext
+	doc? ( >=dev-python/sphinx-2 )
+	python? ( ${PYTHON_DEPS} )
+	test? ( ${RDEPEND} )
+"
+
+PATCHES=(
+	"${FILESDIR}"/fontforge-doc-no-warn-error.patch
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DOCS=$(usex doc ON OFF)
+		-DENABLE_LIBGIF=$(usex gif ON OFF)
+		-DENABLE_LIBJPEG=$(usex jpeg ON OFF)
+		-DENABLE_LIBPNG=$(usex png ON OFF)
+		-DENABLE_LIBREADLINE=$(usex readline ON OFF)
+		-DENABLE_LIBSPIRO=OFF # No package in Gentoo
+		-DENABLE_LIBTIFF=$(usex tiff ON OFF)
+		-DENABLE_MAINTAINER_TOOLS=OFF
+		-DENABLE_PYTHON_EXTENSION=$(usex python ON OFF)
+		-DENABLE_PYTHON_SCRIPTING=$(usex python ON OFF)
+		-DENABLE_TILE_PATH=ON
+		-DENABLE_WOFF2=$(usex woff2 ON OFF)
+	)
+
+	if use gtk || use X; then
+		mycmakeargs+=(
+			-DENABLE_GUI=ON
+			# Prefer GTK over X11 if both USE flage are enabled
+			-DENABLE_X11=$(usex gtk OFF ON)
+		)
+	else
+		mycmakeargs+=( -DENABLE_GUI=OFF )
+	fi
+
+	if use python; then
+		python_setup
+		mycmakeargs+=( -DPython3_EXECUTABLE="${PYTHON}" )
+	fi
+
+	if use truetype-debugger ; then
+		local ft2="${ESYSROOT}/usr/include/freetype2"
+		local ft2i="${ft2}/internal4fontforge"
+		mycmakeargs+=(
+			-DENABLE_FREETYPE_DEBUGGER="${ft2}"
+			-DFreeTypeSource_INCLUDE_DIRS="${ft2};${ft2i}/include;${ft2i}/include/freetype;${ft2i}/src/truetype"
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	docompress -x /usr/share/doc/${PF}/html
+	einstalldocs
+	find "${ED}" -name '*.la' -type f -delete || die
+}