media-libs/babl: 0.1.62, EAPI 7, drop ltprune, sync 9999

Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-2.3.50, Repoman-2.3.11

1 files changed, 54 insertions, 0 deletions

diff --git a/media-libs/babl/babl-0.1.62.ebuild b/media-libs/babl/babl-0.1.62.ebuild
new file mode 100644
index 000000000000..c6f18423b435
--- /dev/null
+++ b/media-libs/babl/babl-0.1.62.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == *9999* ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/babl.git"
+	SRC_URI=""
+else
+	SRC_URI="http://ftp.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A dynamic, any to any, pixel format conversion library"
+HOMEPAGE="http://www.gegl.org/babl/"
+
+LICENSE="LGPL-3"
+SLOT="0"
+IUSE="altivec cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_mmx cpu_flags_x86_f16c"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2.2
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
+src_configure() {
+	# Automagic rsvg support is just for website generation we do not call,
+	#     so we don't need to fix it
+	# w3m is used for dist target thus no issue for us that it is automagically
+	#     detected
+	econf \
+		--disable-docs \
+		--disable-static \
+		--disable-maintainer-mode \
+		$(use_enable altivec) \
+		$(use_enable cpu_flags_x86_f16c f16c) \
+		$(use_enable cpu_flags_x86_mmx mmx) \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable cpu_flags_x86_sse2 sse2) \
+		$(use_enable cpu_flags_x86_sse3 sse3) \
+		$(use_enable cpu_flags_x86_sse4_1 sse4_1)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}