media-libs/ffmpegsource: add 2.40

Closes: https://bugs.gentoo.org/851066
Closes: https://bugs.gentoo.org/834381
Closes: https://bugs.gentoo.org/859865
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 66 insertions, 26 deletions

diff --git a/media-libs/ffmpegsource/Manifest b/media-libs/ffmpegsource/Manifest
index 31437963fc7a..e72577602b7a 100644
--- a/media-libs/ffmpegsource/Manifest
+++ b/media-libs/ffmpegsource/Manifest
@@ -1 +1,2 @@
 DIST ffmpegsource-2.23.tar.gz 488940 BLAKE2B 0e565a02606a73ea0b6ee7bce64fcaea825a2beb473127b4d9c768981519e92cf29bd792b1524369fb44344ce63cb0777adb672f6ee1ec5eae35d92ed549748e SHA512 dbbc3c53062f9b66beeea57b57250abbc331807aad9300966ace4ddd3603273c6345e20d105b668cd852442b494e047ade8b8b1d8340c464ca748f6b11a5292c
+DIST ffmpegsource-2.40.tar.gz 140356 BLAKE2B 57fbc3d979f31108b257b6720045f4e157fca6714bf0f8601e8123c0026a14bb55d343549ff6b246b55a44b4f69c541c58f4b19f1051e338f1f97b2b7557b6de SHA512 407c4b0871f5046b9d364c2946eae88c46eec381b5748530d82918742fd4a36849de590024f8235af2785bd631c0299e591499dc43ae157ff2c6a6f2dab78b67
diff --git a/media-libs/ffmpegsource/ffmpegsource-2.40.ebuild b/media-libs/ffmpegsource/ffmpegsource-2.40.ebuild
new file mode 100644
index 000000000000..1ea646b97aa7
--- /dev/null
+++ b/media-libs/ffmpegsource/ffmpegsource-2.40.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+QA_PKGCONFIG_VERSION=$(ver_cut 1-2)
+inherit autotools
+
+DESCRIPTION="A libav/ffmpeg based source library for easy frame accurate access"
+HOMEPAGE="https://github.com/FFMS/ffms2"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/FFMS/ffms2.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/FFMS/ffms2/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/ffms2-${PV}
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/4"
+
+RDEPEND="
+	>=media-video/ffmpeg-2.4:=
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	# Cheesy hack from autogen.sh
+	mkdir src/config || die
+	eautoreconf
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/media-libs/ffmpegsource/ffmpegsource-9999.ebuild b/media-libs/ffmpegsource/ffmpegsource-9999.ebuild
index 6393bcca9c70..1ea646b97aa7 100644
--- a/media-libs/ffmpegsource/ffmpegsource-9999.ebuild
+++ b/media-libs/ffmpegsource/ffmpegsource-9999.ebuild
@@ -1,47 +1,43 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=8
 
-inherit autotools flag-o-matic git-r3
+QA_PKGCONFIG_VERSION=$(ver_cut 1-2)
+inherit autotools
 
 DESCRIPTION="A libav/ffmpeg based source library for easy frame accurate access"
 HOMEPAGE="https://github.com/FFMS/ffms2"
-EGIT_REPO_URI="https://github.com/FFMS/ffms2.git"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/FFMS/ffms2.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/FFMS/ffms2/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/ffms2-${PV}
+
+	KEYWORDS="~amd64 ~x86"
+fi
 
 LICENSE="MIT"
 SLOT="0/4"
-KEYWORDS=""
 
 RDEPEND="
+	>=media-video/ffmpeg-2.4:=
 	sys-libs/zlib
-	>=media-video/ffmpeg-2.4:0=
-"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
 "
-
-ffms_check_compiler() {
-	if [[ ${MERGE_TYPE} != "binary" ]] && ! test-flag-CXX -std=c++11; then
-		die "Your compiler lacks C++11 support. Use GCC>=4.7.0 or Clang>=3.3."
-	fi
-}
-
-pkg_pretend() {
-	ffms_check_compiler
-}
-
-pkg_setup() {
-	ffms_check_compiler
-}
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
 
 src_prepare() {
-	mkdir -p "${S}/src/config"
-	default_src_prepare
+	default
+
+	# Cheesy hack from autogen.sh
+	mkdir src/config || die
 	eautoreconf
 }
 
 src_install() {
-	default_src_install
+	default
+
 	find "${ED}" -name '*.la' -delete || die
 }